Question

我有包含混合数据的XML文件，其中一些必须被复制，但其中一些必须使用xslt v 1.0基于分隔符进行拆分和复制

输入就像这样：

<class id=1>
  <teacher id=100>
    Some Teacher
  </teacher>
  <pupils>
    101,boy,John;102,girl,Anna;103,boy,Tom
  </pupils>
</class>

我必须将其转换为以下格式：

<class id=1>
  <teacher id=100>
    Some Teacher
  </teacher>
  <pupil id=101>
    <gender id="boy">
      <name>
        John
      </name>
    </gender>
  </pupil>
  <pupil id=102>
    <gender id="girl">
      <name>
        Anna
      </name>
    </gender>
  </pupil>
  <pupil id=103>
    <gender id="boy">
      <name>
        Tom
      </name>
    </gender>
  </pupil>
</class>

非常感谢你如何解决这个问题。

Answer 1

以这种方式试试吗？

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="pupils">
    <xsl:call-template name="tokenize">
        <xsl:with-param name="text" select="normalize-space(.)"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="';'"/>
        <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" />
        <xsl:if test="$token">
            <pupil id="{substring-before($token, ',')}">
                <gender id="{substring-before(substring-after($token, ','), ',')}">
                <name>
                    <xsl:value-of select="substring-after(substring-after($token, ','), ',')" />
                </name>
                </gender>
                </pupil>
        </xsl:if>
        <xsl:if test="contains($text, $delimiter)">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>

</xsl:stylesheet>

xslt使用嵌套模板转换结构化数据 - 将属性拆分和复制为子字符串

1 个答案: