Question

我正在使用CGI和HTML::Template。我需要在包含<form>标记的所有模板中添加以下标记（标记应添加到<form>标记内）。

<input type="hidden" value="TO_BE_PARSED_FROM_CGI">

我不想手动编辑所有模板文件。 HTML::Template中是否有任何方法可以执行此操作？在创建HTML :: Template的构造函数时，我可以传递一些类型的钩子吗？

Answer 1

您不必手动修改所有模板文件。 Perl具有HTML解析器，可以帮助您找到需要进行更改的位置。继续修复模板一次，而不是修改代码，以便每次运行时都执行此操作。下面，我使用\*DATA作为说明目的，但显然，模板文件列表可能来自任何地方。

首先备份文件（更好的是，确保在版本控制系统的分支中执行此操作）。

#!/usr/bin/env perl

use utf8;
use strict;
use warnings;
use open qw[ :std :encoding(UTF-8) ];

use HTML::TokeParser::Simple;

run(\@ARGV);

sub run {
    my $argv = shift;
    my $parser = HTML::TokeParser::Simple->new(handle => \*DATA);

    while (my $token = $parser->get_token) {
        print $token->as_is;
        if ($token->is_start_tag('form')) {
            print qq{\n<input type="hidden" name="sid" value="<TMPL_VAR NAME=SID>">\n};
        }
    }
}

__DATA__
<h3>Here is a form:</h3>

<form
    method="POST"
    action="https://example.com/action-action-action.pl"
    id="action"
    name="actionable_form">

<label for="date">Date:</label>
<input type="date" name="date" id="date">

<input type="submit">

</form>

Answer 2

HTML :: Template中是否有可用的方法来执行此操作？

这又一次？ ;）不，您需要阅读和操作DOM以执行您想要的操作。 HTML :: Template仅适用于它的特定标记/标记。将$template->output()存储到变量中。使用Mojo::DOM等解析器读取变量，以查找表单实例并附加内容。这个例子说明了一个解决方案：

#!/usr/bin/perl
use strict;
use warnings;
use Mojo::DOM;

# fake output of $template->output;

my $html = << 'HTML';
  <html>
    <head>
      <title>test</title>
    </head>
    <body>
      <form method="post">
        <input type="text" id="name">
      </form>
    </body>
  </html>
HTML

# you say you want to parse this from CGI
my $value ='foo'; 

# what you want to add
my $addme = "<input type='hidden' value='$value'>";

my $dom = Mojo::DOM->new();

$dom->parse( $html )->at('form')->child_nodes->first->append( $addme )->root;
print $dom;

打印：

  <html>
    <head>
          <title>test</title>
        </head>
        <body>
          <form method="post">
            <input type="hidden" value="foo"><input id="name" type="text">
          </form>
        </body>
  </html>

编辑。

由于我们不知道您在模板中执行的操作，因此最常用的方法是根据现有代码的输出进行任何更改。这意味着您可以安全地在该点之前添加上述方法，但您当前是否打印了模板的输出。您可以使用作为一次性更新提供的代码将更改实际写回模板，而值{而不是foo可以是HTML :: Template参数。

使用HTML :: Template添加标记

2 个答案: