Question

我正在尝试在我的coverage组中创建一个bin来取样n的倍数值（其中n是我的情况下的常数整数15）。到目前为止，我来了使用以下代码：

class rx_port;
      int unsigned rx_rates[];
      ...
      covergroup rx_cov with function sample (int unsigned rate);
           coverpoint rate{
               bins no_rate    = {0};
               bins mul_of_15  = {SOME_PRE_DEFINED_PATTERN};
           }
      endgroup;
      ....
endclass

其中SOME_PRE_DEFINED_PATTERN是从0到系统宏的int数组，步长为15.我不确定这是否是生成此bin的正确/最佳方式。还有更好的建议吗？

Answer 1

如何编写一些辅助函数：

module FIFTEEN;

  class rx_port;

    typedef enum {IS_ZERO, IS_DIVISIBLE_BY_15, IS_NOT_DIVISIBLE_BY_15} rate_type;

    function new;
      rx_cov=new;
    endfunction

    local function rate_type covergroup_helper(input int unsigned i);
      if (i==0)    return IS_ZERO;
      if (i%15==0) return IS_DIVISIBLE_BY_15;
      return IS_NOT_DIVISIBLE_BY_15;
    endfunction

    function sample (input int unsigned i);
      rx_cov.sample(covergroup_helper(i));
    endfunction

    covergroup rx_cov with function sample (rate_type rate);
      coverpoint rate;
    endgroup;
  endclass

  rx_port R = new;

  initial
    begin
      void'(R.sample(0));
      void'(R.sample(30));
      void'(R.sample(31));
      $display("coverage R.rx_cov.get_coverage= %f", R.rx_cov.get_coverage);
    end

endmodule

https://www.edaplayground.com/x/65v7

这里我编写了一个函数来确定它的输入是否可被15整除，另一个函数调用它来进行采样。你可以将这些功能组合在一起，但我喜欢我的例子中的分工。

Answer 2

事实证明，有更好的方法：

module FIFTEEN;

  class rx_port;

    function new;
      rx_cov=new;
    endfunction

    function sample (input int unsigned i);
      rx_cov.sample(i);
    endfunction

    covergroup rx_cov with function sample (int unsigned rate);
      coverpoint rate { 
        bins IS_ZERO                = {0}; 
        bins IS_DIVISIBLE_BY_15     = {[1:$]} with ((item % 15)==0); 
        bins IS_NOT_DIVISIBLE_BY_15 = {[1:$]} with ((item % 15)!=0); 
      }
    endgroup;
  endclass

  rx_port R = new;

  initial
    begin
      void'(R.sample(0));
      void'(R.sample(30));
      void'(R.sample(31));
      $display("coverage R.rx_cov.get_coverage= %f", R.rx_cov.get_coverage);
    end

endmodule

https://www.edaplayground.com/x/3T5v

您可以使用with来指定垃圾箱。所以

bins IS_DIVISIBLE_BY_15     = {[1:$]} with ((item % 15)==0);

为您提供一个可随时将值除以15（但不能为0）和

bins IS_NOT_DIVISIBLE_BY_15 = {[1:$]} with ((item % 15)!=0);

为您提供一个在值不能被15整除时被命中的垃圾箱。

Systemverilog覆盖点为n的倍数

2 个答案: