Question

我使用TMemIniFile来存储配置，我需要按照alpha顺序对这些部分进行排序。

为此，我创建了TMemIniFile的后代

  TRWStudioMemIniFile = class(TMemIniFile)
  public
    procedure UpdateFile; override;
    procedure GetSortedStrings(List: TStrings);
  end;


{ TRWStudioMemIniFile }

procedure TRWStudioMemIniFile.GetSortedStrings(List: TStrings);
var
  I, J: Integer;
  Strings: TStrings;
begin
  List.BeginUpdate;
  try
    Sections.Sort;
    for I := 0 to Sections.Count - 1 do
    begin
      List.Add('[' + Sections[I] + ']');
      Strings := TStrings(Sections.Objects[I]);
      for J := 0 to Strings.Count - 1 do List.Add(Strings[J]);
      List.Add('');
    end;
  finally
    List.EndUpdate;
  end;
end;

procedure TRWStudioMemIniFile.UpdateFile;
var
  List: TStringList;
begin
  List := TStringList.Create;
  try
    GetSortedStrings(List);
    List.SaveToFile(FileName, Encoding);
  finally
    List.Free;
  end;
end;

但它需要访问Sections（实际上是FSections：TStringList，它是TMemIniFile的私有成员）

我创建了一个Helper类，通过属性公开该成员。但是，在Delphi 10.1中不再支持此行为

我开始将TMemIniFile复制/粘贴到我的单元，然后在无休止的过程之后我最终制作整个System.IniFile的副本，只是为了访问FSections。

我的问题是如何访问该FSections成员而无需复制该单元中的所有内容以获得可见性

OR还有另一种方法可以在保存之前对章节进行排序吗？（我只是从FSections调用TStringList.Sort）

Answer 1

您可以使用继承的TStringList方法将这些部分放入您自己的ReadSections()，并根据需要对该列表进行排序，而不是依赖于类型转换和“破解”私有成员。然后使用继承的ReadSectionValues()方法读取每个部分的字符串：

var
  sections: TStringList;
  values: TStringList;
begin
  sections := TStringList.Create;
  try
    ReadSections(sections);
    sections.Sort;

    values := TStringList.Create;
    try
      List.BeginUpdate;
      try
        for I := 0 to sections.Count - 1 do
        begin
          List.Add('[' + sections[I] + ']');

          values.Clear; // Just in case
          ReadSectionValues(sections[i], values);

          for J := 0 to values.Count - 1 do
            List.Add(values[J]);
          List.Add('');
        end;
      finally
        List.EndUpdate;
      end;
    finally
      values.Free;
    end;
  finally
    sections.Free;
  end;
end;

如何在TMemIniFile上对章节进行排序

1 个答案: