Question

如何将任意Groovy地图/列表转换为Groovy提供的配置样式DSL语法？

示例：

def config = [
    'test': 'lalala',
    'nestedObject': [
        foo1: 'foo1 val',
        foo2: 'foo2 val',
        nested2: [
            anInt: 5,
            anArray: ['a', 'b', 'c'],
            anIntArray: [1, 2, 3]
        ]
    ]
]

类似于：

test = 'lalala'
nestedObject {
    foo1 = 'foo1 val'
    foo2 = 'foo2 val'
    nested2 {
        anInt = 5
        anArray = ['a', 'b', 'c']
        anIntArray = [1, 2, 3]
    }
}

更新：

重新拨打这篇文章，明确要求动态/通用的解决方案。
这使它成为一个独特的问题，并且不像下面的假设已知初始状态的地图：How to create ConfigObject using only nested maps in Grails?

Answer 1

如果您事先知道嵌套的Map结构，那么您的解决方案将起作用。如果您需要在未知的任意嵌套Map结构上执行此操作，请尝试以下操作：

import groovy.util.ConfigObject

def mapToConfig
mapToConfig = { Map map ->
    map.collectEntries { k, v ->
        v instanceof Map ? [(k):mapToConfig(v)] : [(k):v]
    } as ConfigObject
}

鉴于您的输入和上面的闭包定义，以下是print语句：

println mapToConfig(config).prettyPrint()

产生此输出：

test='lalala'
nestedObject {
    foo1='foo1 val'
    foo2='foo2 val'
    nested2 {
        anInt=5
        anArray=['a', 'b', 'c']
        anIntArray=[1, 2, 3]
    }
}

Answer 2

只需将每个Map转换为ConfigObject，然后将其打印出来：

import groovy.util.ConfigObject

def config = [
    'test': 'lalala',
    'nestedObject': [
        foo1: 'foo1 val',
        foo2: 'foo2 val',
        nested2: [
            anInt: 5,
            anArray: ['a', 'b', 'c'],
            anIntArray: [1, 2, 3]
        ] as ConfigObject
    ] as ConfigObject
] as ConfigObject

println config.prettyPrint()

所有功劳归于： How to create ConfigObject using only nested maps in Grails?

（我只是想让人们知道你可以在Grails之外做到这一点，最初我没有意识到如何调用漂亮的打印。我对JsonOutput.prettyPrint（）感到困惑）

谢谢@Steinar

如何使用任意Map（动态对象）创建DSL Groovy配置文件

2 个答案: