Question

我使用antlr 4定义自己的语法，我希望根据操作优先级（+ * - /）来构建树。

我发现样本操作优先级（* +）它工作得很好......

我尝试编辑它以添加操作优先级（ - /），但我失败了：（

操作优先级的语法（+ *）是：

 println:PRINTLN  expression SEMICOLON {System.out.println($expression.value);};
 expression returns [Object value]:
  t1=factor {$value=(int)$t1.value;}
  (PLUS t2=factor{$value=(int)$value+(int)$t2.value;})*;

  factor returns [Object value]: t1=term {$value=(int)$t1.value;}
  (MULT t2=term{$value=(int)$value*(int)$t2.value;})*;

 term returns [Object value]:
  NUMBER {$value=Integer.parseInt($NUMBER.text);}
   | ID {$value=symbolTable.get($value=$ID.text);}
   | PAR_OPEN expression {$value=$expression.value;} PAR_CLOSE
   ;
MULT :'*';
PLUS :'+';

MINUS:'-';
DIV:'/' ;

如何向他们添加操作优先级（ - /）？

Answer 1

您通常可以通过定义表达式， term 和 factor 生产规则来解决此问题。这是一个实现一元+和一元的语法（在EBNF中指定），以及4个二进制算术运算符和括号：

start ::= expression
expression ::= term (('+' term) | ('-' term))*
term ::= factor (('*' factor) | ('/' factor))*
factor :: = (number | group | '-' factor | '+' factor) 
group ::= '(' expression ')'

其中number是数字文字。

Answer 2

在ANTLR3（和ANTLR4）中，*和/的优先级可以高于+和-，如下所示：

println
 : PRINTLN  expression SEMICOLON
 ;

expression
 : factor ( PLUS factor 
          | MINUS factor
          )*
 ;

factor
 : term ( MULT term
        | DIV term
        )*
 ;

term
 : NUMBER
 | ID
 | PAR_OPEN expression PAR_CLOSE
 ;

但是在ANTLR4中，这也可行：

println
 : PRINTLN  expression SEMICOLON
 ;

expression
 : NUMBER
 | ID
 | PAR_OPEN expression PAR_CLOSE
 | expression ( MULT | DIV ) expression   // higher precedence
 | expression ( PLUS | MINUS ) expression // lower precedence
 ;

如何在我的语法中执行操作优先级（+ * - /）？

2 个答案: