Question

如果我有一个打开文件的子程序，那么只有在第一次调用subrountine时才能确保它打开它的最佳方法是什么？我有这个，但不确定它是否是最佳实践：

{
my $count = 0;
sub log_msg {
    my ($msg,$name) = @_;

    if ($count == 0) {
        my $log_file_name = "/tmp/" . $name;
        open my $log_fh,">",$log_file_name or  croak "couldn't open $log_file_name : $!";
        print $log_fh "$timestamp: created and opened $log_file_name\n";
    }
    $count++;
    }
}

Answer 1

听起来是使用状态变量的一个很好的理由。将文件句柄存储在持久散列中。

#!/usr/bin/perl

use 5.010;
use strict;
use warnings;

sub log_msg {
  state %fh;
  my ($msg, $name) = @_;

  unless ($fh{$name}) {
    warn "Opening $name\n";
    open $fh{$name}, '>', $name or die $!;
    print {$fh{$name}} scalar localtime, " Opened file\n";
  }

  print {$fh{$name}} $msg, "\n";
}

log_msg('Message1', 'first.log');
log_msg('Message2', 'first.log');
log_msg('MessageA', 'second.log');
log_msg('MessageB', 'second.log');

请注意打印调用中文件句柄周围的额外括号。那是因为print可以用作文件句柄参数。

Answer 2

最好的方法是使用Log::Log4perl，这样您就不必考虑它，而且可以专注于您的实际任务。

除此之外，您可以使用我们在 Effective Perl Programming 中介绍的文件和文件句柄的一些技巧。幸运的是，这也是我们的出版商赠送的free chapter。

简而言之，您不希望在日志记录例程中考虑这一点。这是杂乱的代码。相反，创建一个方法，该方法返回缓存的文件句柄或打开它（这很像你用来ping数据库句柄并在需要时重新连接的方法）：

 sub log_msg {
      my( $self, $msg, $name ) = @_;

      print { $self->get_fh_by_name( $name ) } $msg;
      }

 BEGIN { # to define variables before the subroutine
 my %log_fhs;
 sub get_fh_by_name {
     my( $self, $name ) = @_;

     return $log_fhs{$name} if defined $log_fhs{$name};

     open my $log_fh, catdir( $base_dir, $name ) or croak "...";
     print $logfh ...

     $log_fhs{$name} = $log_fh;
     }
 }

Answer 3

嗯，首先，$count++应该放在你的if语句中，并且可以改为$count=1。您可能还想将$ count重命名为$file_opened_flag或更有意义的内容。除此之外，我认为没有错。

Answer 4

我认为使用本身并没有任何问题，但如果实际上只有1个要跟踪的文件，为什么不在关闭中保留$log_fh并使用if(!$log_fh->opened())代替计数变量？

如何在Perl中打开文件时才打开文件？

4 个答案: