Question

我的userform中有一个多列列表框，我希望得到列表框中所选行中所有元素的值。

这是我的用户形式：{{3} }

就像在照片中一样，我想选择一行，然后点击按钮Associer，我就可以得到这一行的信息了。我可以得到第一列CAN20168301436我希望从整行获取信息。
我该怎么办？
这是我点击的按钮事件：

Private Sub CommandButton3_Click()
   a = ListBoxResultatFind.Text
End Sub

Answer 1

您可以使用此代码

Private Sub CommandButton3_Click()
    Dim strng As String
    Dim lCol As Long, lRow As Long

    With Me.ListBox1 '<--| refer to your listbox: change "ListBox1" with your actual listbox name
        For lRow = 0 To .ListCount - 1 '<--| loop through listbox rows
            If .selected(lRow) Then '<--| if current row selected
                For lCol = 0 To .ColumnCount - 1 '<--| loop through listbox columns
                    strng = strng & .List(lRow, lCol) & " | " '<--| build your output string
                Next lCol
                MsgBox "you selected" & vbCrLf & Left(strng, (Len(strng) - 1)) '<--| show output string (after removing its last character ("|"))
                Exit For '<-_| exit loop
            End If
        Next lRow
    End With
End Sub

Answer 2

无需循环整个列表 - 为了获取所选项目行，您可以使用ListIndex属性。然后，您可以使用List(Row, Column)属性来检索数据，如@DragonSamu和@ user3598756中的示例所示：

'***** Verify that a row is selected first
If ListBoxResultatFind.ListIndex > -1 And ListBoxResultatFind.Selected(ListBoxResultatFind.ListIndex) Then
    '***** Use the data - in my example only columns 2 & 3 are used
    MsgBox ListBoxResultatFind.List(ListBoxResultatFind.ListIndex, 1) & ":" & ListBoxResultatFind.List(ListBoxResultatFind.ListIndex, 2)
End If

Answer 3

使用单个列，您可以检索以下值：

Dim str as String
str = me.ListBox1.Value

使用多列，您可以检索如下值：

Dim strCol1 as String
Dim strCol2 as String
Dim strCol3 as String
strCol1 = ListBox1.List(0, 1)
strCol2 = ListBox1.List(0, 2)
strCol3 = ListBox1.List(0, 3)

或者您可以将所有数据添加到1个字符串中：

Dim strColumns as String
strColumns = ListBox1.List(0, 1) + " " + ListBox1.List(0, 2) + " " + ListBox1.List(0, 3)

Answer 4

这是一个6列的列表框，第3列是乘数，因此是“（x）”。您也可以将列表重新排列为您喜欢的方式。

Private Function selList() As String
Dim i As Long

For i =LBound(lstListBox1.List) To UBound(lstListBox1.List)
    If lstListBox1.Selected(i) Then
        selList = selList & lstListBox1.List(i) & " " & lstListBox1.List(i, 1) _
        & "(x" & lstListBox1.List(i, 3) & ")" & " " & lstListBox1.List(i, 2) & " " & lstListBox1.List(i, 4) & ", "
    End If
Next i

If selList= "" Then
    selList= ""
Else
    selList= Left(selList, Len(selList) - 2)
End If

MsgBox selList
End Function

如何在多列列表框中获取选定值

4 个答案: