Question

我已经构建了一个加载自制.dylib的应用程序，这个.dylib必须调用另一个.dylib。

我在OS X上使用Qt。当我在Qt Creator中时，我可以调试/发布它的工作原理。当我单击.app和我的应用程序使用的所有.dylib时，它也可以工作。位于.app / Contents / Frameworks中。我的问题是部署。当我运行macdeployqt时，所有工作和.dmg都会生成但是当我启动这个.dmg时，会发生错误。

此错误是逻辑错误，因为主.dylib调用的.dylib不在文件夹.app / Contents / Frameworks中。如果我在此文件夹中将其添加，我就不知道如何添加它会失败。它也是逻辑因为app不会调用第二个.dylib而是主dylib。没有app文件夹......

Answer 1

在使用macdeployqt工具之前，必须将所需的库复制到应用程序包中。您可以通过添加主目标所依赖的custom targets从应用程序本身的项目文件中执行复制。这些目标将是dylib的副本，您将从构建目录中的其他位置复制它们。

通常，你有一个顶级子目录项目来构建库和你的应用程序，例如：

+--- lib-dylib-32920629
    +--- lib-dylib-32920629.pro
    +--- lib1
    |   +--- lib1.pro
    |   +--- lib1.cpp
    |   \--- lib1.h
    \--- main
        +--- main.pro
        \--- main.cpp

从https://github.com/KubaO/stackoverflown/tree/master/questions/lib-dylib-39206929

下载此项目

lib-dylib-39206929.pro

TEMPLATE = subdirs
SUBDIRS += lib1 main
main.depends += lib1

LIB1 / lib1.pro

QT = core
CONFIG += c++11
TEMPLATE = lib
HEADERS += lib1.h
SOURCES += lib1.cpp

LIB1 / lib1.h

#ifndef LIB1_H
#define LIB1_H

#include <QObject>

class Lib1 {
public:
    QString text();
};

#endif

LIB1 / lib1.cpp

#include "lib1.h"

QString Lib1::text() {
    return QStringLiteral("Hello from Lib1");
}

主/ main.pro

可以使用自定义deployLib函数将库部署到应用程序包中：

QT = widgets
CONFIG += c++11
TEMPLATE = app
SOURCES += main.cpp
LIBS += -L../lib1 -llib1
INCLUDEPATH += ..
DEPENDPATH += ..

defineReplace(libVersions) {
   # libVersions(1,2,3) - returns .1.2.3. .1.2. .1. .
   versions=.$${1}.$${2}.$${3}. .$${1}.$${2}. .$${1}. .
   return($$versions)
}
defineReplace(dylibs) {
   # dylibs(base,1,2,3) - returns libbase.1.2.3.dylib libbase.1.2.dylib ... libbase.dylib
   base = $$1
   versions = $$libVersions("$$2","$$3","$$4")
   libs =
   for (version, versions): libs += lib$${base}$${version}dylib
   return($$libs)
}
defineTest(deployLib) {
   # deployLib(target,target2path,target2,1,2,3)
   #   deploys target2path/libtarget2.1.2.3.dylib,... to the target's application bundle
   target = $$1
   libpath = $$2
   libtarget = $$3
   libs = $$dylibs($$libtarget,$$4,$$5,$$6)
   targetdir = $${target}.app/Contents/MacOS
   mktargetdir = "(test -d $$targetdir/ || mkdir -p $$targetdir/)"
   for (lib, libs) {
      out = $$targetdir/$$lib
      $${lib}.target = $$out
      $${lib}.commands = $$mktargetdir
      $${lib}.commands += "&& $$QMAKE_COPY_FILE $$libpath/$$libtarget/$$lib $$out"
      export($${lib}.target)
      export($${lib}.commands)
      QMAKE_EXTRA_TARGETS += $$lib
      PRE_TARGETDEPS += $$out
   }
   export(QMAKE_EXTRA_TARGETS)
   export(PRE_TARGETDEPS)
   return(true)
}

macx {
   deployLib(main, .., lib1, 1, 0, 0)
}

主/ main.cpp中

#include "lib1/lib1.h"
#include <QtWidgets>

int main(int argc, char ** argv) {
    QApplication app{argc, argv};
    Lib1 lib1;
    QLabel label{lib1.text()};
    label.setMinimumSize(200, 200);
    label.setFont(QFont{"Helvetica", 20});
    label.show();
    return app.exec();
}

如何使用调用其他.dylib的外部.dylib部署应用程序？

1 个答案: