Question

我正在与必须识别excel文件中的某些变量的人合作。目前，我正在使用的人有大量的文件夹和子文件夹，其中包含Excel文档。他正在使用VBA代码在文件夹中查找子文件夹，然后返回路径，然后创建指向子文件夹的超链接（这不是下面VBA代码的一部分）并查看其中的所有excel文件，无论主文件夹中的子文件夹级别如何。

以下是代码：

    Sub GetFolders()
Dim path As String
Dim folder As String
Dim row As Integer


path = "your directory here"
folder = Dir(path, vbDirectory)
row = 1

Do While folder <> ""
If (GetAttr(path & folder) And vbDirectory) = vbDirectory Then
    Cells(row, 1) = path & folder
    row = row + 1
End If
folder = Dir()
Loop

End Sub

这很好，但我知道必须有更好的方法。如何操作此代码以返回在文件夹中包含的子文件夹中的文件夹或B）中找到的任何excel文件的COLUMN HEADERS。我希望将这些文件返回到excel电子表格中，以便不需要打开100个excel文档，而只需要打开这个文档，然后我们就可以识别需要进一步调查的任何Excel电子表格，而忽略其余的。

Answer 1

您可以使用ADO查询它们（根据需要调整连接字符串）：

'Requires reference to Microsoft ActiveX Data Objects #.# Library
Private Function GetHeaders(filepath As String) As String()
    Dim output() As String
    Dim ado As New ADODB.Connection
    output = Split(vbNullString)

    With ado
        .Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source='" & filepath & "';" & _
              "Extended Properties=""Excel 12.0 Xml;HDR=YES;IMEX=1;"";"
        With .OpenSchema(adSchemaTables)
            Dim table As String
            Dim columns As ADODB.Recordset
            Do While Not .EOF
                table = .Fields("TABLE_NAME")
                Set columns = ado.OpenSchema(adSchemaColumns, Array(Empty, Empty, table))
                With columns
                    Do While Not .EOF
                        ReDim Preserve output(UBound(output) + 1)
                        output(UBound(output)) = table & .Fields("COLUMN_NAME")
                        .MoveNext
                    Loop
                End With
                .MoveNext
            Loop
        End With
    End With
    GetHeaders = output
End Function

然后为您找到的每个文件调用它：

Sub Example()
    Dim headers() As String
    Dim i As Long
    headers = GetHeaders("C:\Foo\Bar.xlsx")
    For i = LBound(headers) To UBound(headers)
        Debug.Print headers(i)
    Next i
End Sub

请注意，这假设您不知道工作表名称，并且需要获取所有的标题。输出数组中的字符串将采用Sheet$Field的形式，但可以根据需要进行调整。

Answer 2

由于ADODB中的限制，col标头中的单元格限制为255个字符。

使用VBA从Excel文件中检索列标题

2 个答案: