Question

我有windows环境，我自己的kafka和zookeeper运行。为了使用自定义对象，我开始使用Avro。但我需要启动注册表。下载了Confluent平台并运行了这个：

$ ./bin/schema-registry-start ./etc/schema-registry/schema-registry.properties
/c/Confluent/confluent-3.0.0-2.11/confluent-3.0.0/bin/schema-registry-run-class: line 103: C:\Program: No such file or directory

然后我在安装页面上看到了这个：

＆＃34; Confluent目前不支持Windows。 Windows用户可以下载并使用zip和tar存档，但必须直接运行jar文件，而不是使用bin /目录中的包装脚本。＆＃34;

我想知道如何在Windows环境中启动融合架构注册表？

查看脚本的内容，很难解读。

由于

Answer 1

有人创建了Windows .bat文件，如Ewen Cheslack-Postava建议的那样

https://github.com/renukaradhya/confluentplatform/tree/master/bin/windows

我将schema-registry-run-class.bat和schema-registry-start.bat保存到我的\confluent\bin\windows目录中，然后能够运行Schema Registry

C:\confluent\bin\windows\schema-registry-start.bat C:\confluent\etc\ schema-registry\schema-registry.properties

Answer 2

目前Confluent Platform没有附带任何Windows脚本。但是，如果您熟悉运行Java应用程序，则可以编写自己的应用程序。 schema-registry-server-start脚本（以及它依赖的schema-registry-run-class脚本）执行诸如处理-daemon模式，设置Java内存选项，设置默认日志配置等操作，但最终关键部分是他们用io.confluent.kafka.schemaregistry.rest.SchemaRegistryMain作为主要方法执行Java。您可能还会发现来自Kafka的kafka-run-class.bat是一个有用的基础：https://github.com/apache/kafka/blob/trunk/bin/windows/kafka-run-class.bat

Answer 3

问题可能是Windows环境的JAVA_HOME环境设置中存在空格（由＆＃34; C：\ Program＆＃34;而不是＆＃34; C：\ Program Files的错误消息证明） ......＆＃34;。

您可以通过添加替换最后一个＆＃34; exec＆＃34;来确定最终java调用的EXACT语法以启动schema_registry。在schema-registry-run-class脚本中，单词＆＃34; echo＆＃34;。你会看到相当复杂的命令

/Library/Java/JavaVirtualMachines/jdk1.8.0_91.jdk/Contents/Home/bin/java -Xmx512M -server -XX:+UseG1GC -XX:MaxGCPauseMillis=20 -XX:InitiatingHeapOccupancyPercent=35 -XX:+DisableExplicitGC -Djava.awt.headless=true -Dcom.sun.management.jmxremote -Dcom.sun.management.jmxremote.authenticate=false -Dcom.sun.management.jmxremote.ssl=false -Dlog4j.configuration=file:/opt/confluent/bin/../etc/schema-registry/log4j.properties -cp :/opt/confluent/bin/../package-schema-registry/target/kafka-schema-registry-package-*-development/share/java/schema-registry/*:/opt/confluent/bin/../share/java/confluent-common/*:/opt/confluent/bin/../share/java/rest-utils/*:/opt/confluent/bin/../share/java/schema-registry/* io.confluent.kafka.schemaregistry.rest.SchemaRegistryMain

该命令归结为＆＃34; java [core-java-opts] [java-defines] -cp [classpath] io.confluent.kafka.schemaregistry.rest.SchemaRegistryMain

如果您更换＆＃34; / opt / confluent＆＃34;参考Confluent安装的实际位置，我怀疑你会有更好的运气。

注意：我更喜欢在Windows上将Java安装到客户位置（例如＆＃34; C：\ java8＆＃34;，因为许多标准脚本在C：\ Program Files部署位置都会出现问题。

Answer 4

我使用cygwin成功运行cmd.exe中的汇合工具。

C:\>c:\cygwin64\bin\bash -l /cygdrive/c/confluent/4.0.0/bin/kafka-avro-console-consumer --bootstrap-server <my_server_name>:9092 --topic <my_topic> --property schema.registry.url=http://<my_schema_registry_url>:8081 >> tmp.txt

Answer 5

模式注册表运行类bat文件的代码为：另存为schema-registry-run-class.bat

@echo off

setlocal EnableExtensions EnableDelayedExpansion
pushd %~dp0..\..
set BASE_DIR=%CD%
popd

for %%i in (%BASE_DIR%/package-schema-registry/target/kafka-schema-registry-package-*-development) do (
    call :concat %%i/share/java/schema-registry/*
)

for %%i in (confluent-common, rest-utils, schema-registry) do (
    call :concat %BASE_DIR%/share/java/%%i/*
)

rem Log4j settings
IF ["%SCHEMA_REGISTRY_LOG4J_OPTS%"] EQU [""] (
    if exist %~dp0../../etc/schema-registry/log4j.properties (
        set SCHEMA_REGISTRY_LOG4J_OPTS=-Dlog4j.configuration=file:%~dp0../../etc/schema-registry/log4j.properties
    ) else (
        set SCHEMA_REGISTRY_LOG4J_OPTS=-Dlog4j.configuration=file:%BASE_DIR%/config/log4j.properties
    )
)

rem JMX settings
IF ["%SCHEMA_REGISTRY_JMX_OPTS%"] EQU [""] (
    set SCHEMA_REGISTRY_JMX_OPTS=-Dcom.sun.management.jmxremote -Dcom.sun.management.jmxremote.authenticate=false  -Dcom.sun.management.jmxremote.ssl=false
)

rem JMX port to use
IF ["%JMX_PORT%"] NEQ [""] (
    set SCHEMA_REGISTRY_JMX_OPTS=%SCHEMA_REGISTRY_JMX_OPTS% -Dcom.sun.management.jmxremote.port=%JMX_PORT%
)

rem Which java to use
IF ["%JAVA_HOME%"] EQU [""] (
    set JAVA=java
) ELSE (
    set JAVA="%JAVA_HOME%/bin/java"
)

rem Memory options
IF ["%SCHEMA_REGISTRY_HEAP_OPTS%"] EQU [""] (
    set SCHEMA_REGISTRY_HEAP_OPTS=-Xmx512M
)

rem JVM performance options
IF ["%SCHEMA_REGISTRY_JVM_PERFORMANCE_OPTS%"] EQU [""] (
    set SCHEMA_REGISTRY_JVM_PERFORMANCE_OPTS=-server -XX:+UseG1GC -XX:MaxGCPauseMillis=20 -XX:InitiatingHeapOccupancyPercent=35 -XX:+DisableExplicitGC -Djava.awt.headless=true
)

set COMMAND=%JAVA% %SCHEMA_REGISTRY_HEAP_OPTS% %SCHEMA_REGISTRY_JVM_PERFORMANCE_OPTS% %SCHEMA_REGISTRY_JMX_OPTS% %SCHEMA_REGISTRY_LOG4J_OPTS% -cp %CLASSPATH% %SCHEMA_REGISTRY_OPTS% %*
%COMMAND%

goto :eof
:concat
IF ["%CLASSPATH%"] EQU [""] (
  set CLASSPATH="%1"
) ELSE (
  set CLASSPATH=%CLASSPATH%;"%1"
)

Answer 6

模式注册表bat文件的代码。另存为schema-registry-start.bat


@echo off

%~dp0schema-registry-run-class.bat io.confluent.kafka.schemaregistry.rest.SchemaRegistryMain %*

架构注册表属性文件应如下所示：另存为schema-registry.properties

listeners=http://10.91.31.169:8081
kafkastore.connection.url=10.91.31.169:2181
kafkastore.topic=_schemas
debug=true

在Windows中启动Confluent Schema Registry

6 个答案: