Question

我正在使用MS PowerPoint制作视频课程。

不幸的是，在幻灯片放映过程中，我的工作效率大大降低了：

4次点击以从红笔变为蓝色荧光笔
然后，更换为绿色笔需要再点击4次。

这种情况正在变得令人讨厌，因为这3秒钟不活动的爆发必须进行繁琐的视频编辑以吸引教训。

键盘快捷键（iframe和Ctrl-I）仅在我只为笔和荧光笔使用一种颜色时才有用，并且仅在两者之间切换。

我想知道是否有任何东西可以在每张幻灯片的底部永久显示调色板。我知道这是可能的，因为我使用OfficeOne InkTools在PowerPoint 2013上工作正常，但它没有我想要的所有功能。我有编码经验，如果我走过了需要修改的对象等，我愿意自己制作这个功能。

谢谢你。

Answer 1

有几点想法：

您可以在文件中添加几个VBA例程，如下所示（根据需要调整RGB值）：

Sub Blue()
    With SlideShowWindows(1).View.PointerColor
        .RGB = RGB(0, 0, 255)
    End With
End Sub

Sub Red()
    With SlideShowWindows(1).View.PointerColor
        .RGB = RGB(255, 0, 0)
    End With
End Sub

根据需要为其他颜色添加更多。

然后在幻灯片（或主控）上绘制几个矩形或其他形状，并为每个矩形指定一个RUN MACRO：蓝色（或红色或其他）的动作设置。

你可以将它们变得透明，这样任何观看演示文稿的人都不会觉得它们有任何形状。

按Ctrl + A将指针更改为箭头（这样您可以单击某些内容），单击所需颜色的形状，然后按Ctrl + P将光标移回笔，以便绘制。 ..以所选颜色。

==================

另一种完全不同的方法是在两张不同的幻灯片上预先添加注释，并在它们之间或一张幻灯片上进行过渡，并根据需要为它们设置动画。

Answer 2

如果你想在幻灯片放映期间拥有某种动态可见/隐藏的交互式工具栏，就像上面那样，你可以用你需要颜色的多个按钮为你的项目添加一个表单，并调用Sub来打开那个表单。单击幻灯片上的对象（可见或不可见）。为此，请向幻灯片（或主控）添加形状，并设置其鼠标单击操作以在标准模块中运行此宏：

Sub ChangePenColour()
  frmChangePenColour.Show
End Sub

然后创建一个名为frmChangePenColour的表单并向其添加7个按钮，称为btn1到btn6和btnCancel。

然后将此代码添加到表单中：

' =======================================================
' Pen Colour Demo by YOUpresent
' Visit http://youpresent.co.uk for more PowerPoint stuff
' =======================================================
Option Explicit

Private Sub btn1_Click()
  ChangePointerColor btn1.BackColor
  Unload Me
End Sub

Private Sub btn2_Click()
  ChangePointerColor btn2.BackColor
  Unload Me
End Sub

Private Sub btn3_Click()
  ChangePointerColor btn3.BackColor
  Unload Me
End Sub

Private Sub btn4_Click()
  ChangePointerColor btn4.BackColor
  Unload Me
End Sub

Private Sub btn5_Click()
  ChangePointerColor btn5.BackColor
  Unload Me
End Sub

Private Sub btn6_Click()
  ChangePointerColor btn6.BackColor
  Unload Me
End Sub

Private Sub UserForm_Activate()
  CentreForm Me
End Sub

Private Sub UserForm_Initialize()
  With SlideShowWindows(1).View.Slide.Design.SlideMaster.Theme
    btn1.BackColor = .ThemeColorScheme(msoThemeAccent1).RGB
    btn2.BackColor = .ThemeColorScheme(msoThemeAccent2).RGB
    btn3.BackColor = .ThemeColorScheme(msoThemeAccent3).RGB
    btn4.BackColor = .ThemeColorScheme(msoThemeAccent4).RGB
    btn5.BackColor = .ThemeColorScheme(msoThemeAccent5).RGB
    btn6.BackColor = .ThemeColorScheme(msoThemeAccent6).RGB
  End With
End Sub

Sub ChangePointerColor(lRGB As Long)
  With SlideShowWindows(1).View
    .PointerColor = lRGB
    .PointerType = ppSlideShowPointerPen
  End With
End Sub

Private Sub btnCancel_Click()
  Unload Me
End Sub

' Centres a form wrt the PowerPoint application window
Public Sub CentreForm(thisForm As Object)
  On Error Resume Next
  ' Position in the centre of the PowerPoint window
  With thisForm
    .Left = Application.Left + ((Application.Width / 2) - (.Width / 2))
    .Top = Application.Top + ((Application.Height / 2) - (.Height / 2))
  End With
  If Err Then Debug.Print Err & Err.Description & " in CentreForm"
  On Error GoTo 0
End Sub

现在，当您运行幻灯片放映时，您可以单击所选的活动形状以打开颜色选择器并开始以该颜色进行注释。

然后，如果您希望在幻灯片放映开始时自动显示该工具栏，并且在单击颜色时不会消失，则可以添加此子项：

Sub OnSlideShowPageChange(ByVal Wn As SlideShowWindow)
  frmChangePenColour.Show
End Sub

并将表单的ShowModal属性更改为false。

您可能想要调整UI逻辑，但这应该足以让您前进。

在幻灯片放映期间永久显示调色板 - MS PowerPoint

2 个答案: