Question

我创建了一个拼图，你可以拖放16件。我使用了一个数组，所以代码不会太大。现在我想添加一个功能，一旦你到达目的地，每个拼图就会卡入正确的位置。

我的问题是我不知道如何创建一个可以实现我的目标的数组。我尝试了以下（没有数组，但是如果我用所有16个拼图块创建了太多代码）：

menu.findItem(R.id.overflow_about_us).getActionView().setBackgroundColor(Color.BLUE);

代码：

if(target1_mc.hitTestObject(piece1_mc.tar1_mc))
        {
            piece1_mc.x = 207,15;
            piece1_mc.y = 119,25;
        }

Answer 1

有几种方法可以实现这一目标。最简单的方法是为您的作品添加动态属性，以存储该作品的目标（正确的位置对象）。

var puzzleArr:Array = []; //you don't really even need the array in my example
var tmpPiece:MovieClip; //this stores the current dragging piece, and I also reuse it in the loop below 

//I don't like typing a lot, so let's use a loop for all 16 pieces and their targets
for(var i:int=1;i<=16;i++){
    tmpPiece = this["piece" + i + "_mc"]; //get a reference to piece whose number matches i

    if(!tmpPiece){
        trace("Sorry - there is no piece called: 'piece" + i + "_mc'");
        continue;
    }

    //give the piece a dynamic property that is a reference to it's target spot
    tmpPiece.targetTile = this["target" + i + "_mc"];

    if(!tmpPiece.targetTile){
        trace("Sorry - there is no target called: 'target" + i + "_mc'");
        continue;
    }

    tmpPiece.tar_mc = tmpPiece["tar" + i + "_mc"]; //it would be better to just take the number out of each pieces tar_mc child object making this line uneccessary

    //track where the piece is placed
    tmpPiece.startingPos = new Point(tmpPiece.x, tmpPiece.y);

    //only add the mouse down listener to the piece (not mouse up)
    tmpPiece.addEventListener(MouseEvent.MOUSE_DOWN, drag);

    //if still using the array, add the piece to the array
    puzzleArr.push(tmpPiece);
}

接下来，仅在拖动时添加鼠标移动侦听器

function drag(event:MouseEvent):void {
    tmpPiece = event.currentTarget as MovieClip; //assign the dragging object to the tmpPiece var


    tmpPiece.startDrag();

    //add a mouse move listener so you can check if snapping is needed
    tmpPiece.addEventListener(MouseEvent.MOUSE_MOVE, moving);

    //add the mouse up listener to the stage - this is good because if you drag fast, the mouse can leave the object your dragging, and if you release the mouse then it won't trigger a mouse up on the dragging object
    stage.addEventListener(MouseEvent.MOUSE_UP, drop);
}

function drop(event:MouseEvent):void {
    //stop all dragging
    this.stopDrag();

    if(tmpPiece){
        //remove the mouse move listener
        tmpPiece.removeEventListener(MouseEvent.MOUSE_MOVE, moving);

        //ensure a snap at the end of the drag
        if(!checkSnapping()){
           //if not snapped, reset it's position
           tmpPiece.x = tmpPiece.startingPos.x;
           tmpPiece.y = tmpPiece.startingPos.y;
        } 
    }

    //remove the mouse up listener
    stage.removeEventListener(MouseEvent.MOUSE_UP, drop);
}

现在让我们在鼠标移动处理程序中进行捕捉：

function moving(e:MouseEvent = null):void {
    checkSnapping();
}

//return true if snapped
function checkSnapping():Boolean {
    if(tmpPiece && tmpPiece.tar_mc.hitTestObject(tmpPiece.targetTile)){
        tmpPiece.x = tmpPiece.targetObj.x - tmpPiece.tar_mc.x;
        tmpPiece.y = tmpPiece.targetObj.y - tmpPiece.tar_mc.y;
        return true;
    }

    return false;
}

Answer 2

for (var i:int = 0; i < puzzleArray.length; i++)
{
    if(puzzleArray[i].hitTestObject(puzzleArray[i]._target))
    {
        puzzleArray[i].x = puzzleArray[i]._xGoal;
        puzzleArray[i].y = puzzleArray[i]._yGoal;
    }
}

显然，您需要在拼图块对象（_xGoal，_yGoal，_target）中添加一些属性，然后您就可以这样做了。我喜欢。你可以使用一个循环，但只有当它们有某种顺序时。如果它们的大小不同并且在网格中，那么您显然只需手动输入这些内容。

如果它们在网格中并且每个部分的大小相同，请告诉我您是否需要帮助在循环中创建这些属性。

使用ActionScript 3为捕捉函数创建数组

2 个答案: