Question

我有xml

<PhoneNumberDetails>
    <PhoneNumber>
        <Number>4162880001</Number>
        <TimeStamp>2016-08-16T07:07:44-04:00</TimeStamp>
    </PhoneNumber>
    <PhoneNumber>
        <Number>4162880002</Number>
        <TimeStamp>2016-08-16T07:07:44-04:00</TimeStamp>
    </PhoneNumber>
</PhoneNumberDetails>

这是XSL的输入。在这个XSL中，我从上一个XSLT中存储的上下文变量中检索一个电话号码，如果它匹配上面xml中的任何电话号码，我需要将TimeStamp更新为新的当前时间戳。我需要这方面的帮助。

XSLT代码：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:dp="http://www.datapower.com/extensions" xmlns:date="http://exslt.org/dates-and-times" extension-element-prefixes="dp date" exclude-result-prefixes="dp">
    <xsl:variable name="currentTimeStamp" select="date:date-time()"/>
    <xsl:output method="xml"/>
    <xsl:template match="PhoneNumberDetails">
        <xsl:variable name="savedPhoneNum" select="dp:variable('var://context/name/phonenum')"/>
        <xsl:choose>
            <xsl:when test="/*[local-name()='PhoneNumberDetails']/*[local-name()='PhoneNumber']/*[local-name()='Number']=$savedPhoneNum">
                <xsl:copy-of select="."/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="phonenumber"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template name="phonenumber" match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="PhoneNumberDetails">
        <PhoneNumberDetails>
            <xsl:apply-templates select="@* | *"/>
            <PhoneNumber>
                <Number>
                    <xsl:value-of select="dp:variable('var://context/name/phonenum')"/>
                </Number>
                <TimeStamp>
                    <xsl:value-of select="$currentTimeStamp"/>
                </TimeStamp>
            </PhoneNumber>
        </PhoneNumberDetails>
    </xsl:template>
</xsl:stylesheet>

如果电话号码与XML中的任何数字都不匹配，我需要在上面的xml中添加一个新元素，这个部分有效。例如，

<PhoneNumber>
    <Number>New number</Number>
    <TimeStamp>Current TimeStamp</TimeStamp>
</PhoneNumber>

Answer 1

我建议你从这样的事情开始。请勿使用绝对路径选择电话号码，请在模板匹配的上下文节点中使用它。

<xsl:template match="PhoneNumber">
  <xsl:copy>
    <xsl:copy-of select="Number"/>
    <xsl:variable name="savedPhoneNum" select="dp:variable('var://context/name/phonenum')"/>
    <TimeStamp>
       <xsl:choose>
        <xsl:when test="Number=$savedPhoneNum">
             <xsl:value-of select="$currentTimeStamp"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="TimeStamp"/>
        </xsl:otherwise>
      </xsl:choose>
    </TimeStamp>
  </xsl:copy>
</xsl:template>

请注意，我假设您在输入xml的元素上没有（未显示）命名空间。如果是，请保留* [local-name（）=“”]构造，但是必须将名称空间添加到match =“PhoneNumber”和TimeStamp输出中。

Answer 2

为什么你不能做到：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:dp="http://www.datapower.com/extensions" 
xmlns:date="http://exslt.org/dates-and-times" 
extension-element-prefixes="dp date">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:param name="savedPhoneNum" select="dp:variable('var://context/name/phonenum')"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="TimeStamp[../Number=$savedPhoneNum]">
    <xsl:copy>
        <xsl:value-of select="date:date-time()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="PhoneNumberDetails[not(PhoneNumber/Number=$savedPhoneNum)]">
    <xsl:copy>
        <xsl:apply-templates/>
        <PhoneNumber>
            <Number>New number</Number>
            <TimeStamp>Current TimeStamp</TimeStamp>
        </PhoneNumber>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

通过XSLT修改条件下的XML元素值

2 个答案: