Question

我在Delphi中关于构造函数的一系列问题中的另一个问题。

我有一个具有虚拟构造函数的基类：

TComputer = class(TObject)
public
    constructor Create(Teapot: Integer); virtual;
end;

构造函数对于某人需要调用的时间是虚拟的

var
   computerClass: class of TComputer;
   computer: TComputer;
begin     
   computer := computerClass.Create(nTeapot);

后代中的构造函数为overridden：

TCellPhone = class(TComputer) 
public
   constructor Create(Teapot: Integer); override;
end;

TiPhone = class(TCellPhone ) 
public
   constructor Create(Teapot: Integer); override;
end;

TCellPhone和TiPhone后代各自都有机会进行自己的初始化（不包括在内的成员以便于阅读）。

但是现在我向一些祖先添加了一个重载的构造函数：

TCellPhone = class(TComputer) 
public
   constructor Create(Teapot: Integer); override; overload;
   constructor Create(Teapot: Integer; Handle: string); overload;
end;

TCellPhone中的备用构造函数调用另一个虚拟构造函数，因此它始终获得正确的重写行为：

constructor TCellPhone.Create(Teapot: Integer; Handle: string);
begin
   TCellPhone.Create(Teapot); //call sibling virtual constructor

   FHandle := Handle;
end;

问题是永远不会调用后代，重写的构造函数。实际的堆栈跟踪调用链是：

phone := TiPhone.Create(37, 'spout')
   constructor TCellPhone.Create(Teapot: Integer; Handle: string)
      constructor TCellPhone.Create(Teapot: Integer)
         constructor TComputer.Create(Teapot: Integer)
            TObject.Create

对TCellPhone.Create(int)的兄弟调用是虚拟的，应调用TiPhone中的后代，重写方法：

phone := TiPhone.Create(37, 'spout')
   constructor TCellPhone.Create(Teapot: Integer; Handle: string)
      constructor TiPhone.Create(Teapot: Integer)
         constructor TCellPhone.Create(Teapot: Integer)
            constructor TComputer.Create(Teapot: Integer)
               TObject.Create

所以似乎尝试使用兄弟虚拟构造函数是Delphi不能按预期工作。

一个构造函数使用另一个构造函数是不是一个坏主意？设计意图是重载构造函数中的代码是彼此的复制粘贴版本吗？

我在.NET中注意到一些构造函数彼此链接：

public Bitmap(int width, int height) : this(width, height, PixelFormat.Format32bppArgb) {}

public Bitmap(int width, int height, PixelFormat format) {...}

如果出现以下情况，这似乎只是一个问题：

构造函数是虚拟的
重载构造函数

规则是你不能让一个构造函数重载另一个吗？

Answer 1

Errr ..

constructor TCellPhone.Create(Teapot: Integer; Handle: string);
begin
   TCellPhone.Create(Teapot); //call sibling virtual constructor

   FHandle := Handle;
end;

应该是：

constructor TCellPhone.Create(Teapot: Integer; Handle: string);
begin
   Create(Teapot); //call sibling virtual constructor

   FHandle := Handle;
end;

您刚刚创建了一个新的TCellphone实例而没有调用另一个Create方法。

Delphi：重载的虚拟构造函数后代未被重载调用

1 个答案: