Question

我目前正在开发一个多环境perl脚本。众所周知，如果做得不好，环境配置杂耍可能会非常痛苦。由于我的perl脚本必须在配置值过载目的中允许一些命令行参数，我带来了以下解决方案：

package Cfg;
use strict;
use warnings;
my $gEnvironment = "DEBUG";#"PRODUCTION";
my %gConfig = (
  DEBUG=>{MESSAGE=>"This is a dbg env.",URL=>"www.my-dbg-url.org"},
  PRODUCTION=>{MESSAGE=>"This is a prod env.",URL=>"www.shinyprodurl.org"}
);
my $gMessage = defined $gConfig{$gEnvironment} ?
  $gConfig{$gEnvironment}{MESSAGE} : die "Crappy environment";
sub Message { $gMessage = shift(@_) if (@_); $gMessage }
sub Url {
  defined $gConfig{$gEnvironment} ?
    $gConfig{$gEnvironment}{URL} : die "Crappy environment"
}
1;

所以，以下脚本：

use strict;
use warnings;
use Cfg;
print Cfg::Message,"\n";
Cfg::Message("I'm a surcharged message.");
print Cfg::Message;

会产生下一个输出：

This is a dbg env.
I'm a surcharged message.

关键是我想在加载Cfg模块期间定义$ gEnvironment的值。这样我就可以在所有环境中使用相同的配置模块。

这可能吗？

Answer 1

我相信您所使用的自定义import方法就是：

package Cfg;

our $gMessage;

sub import {
    my ($package, $msg) = @_;
    $gMessage = $msg;
}

以及其他地方：

use Cfg "some message";

当你import某个模块时，

use就是perl会调用的内容。有关详细信息，请参阅perldoc -f use。

Answer 2

以下是如何实现您想要的目标，但我认为通过完整的面向对象路线可以更好地满足您的需求。下面的解决方案只需要进行一些修改即可实现：

package Cfg;

use strict; use warnings;
use Carp;

my $gEnvironment = "DEBUG"; # default
my $gMessage;

my %gConfig = (
    DEBUG => {
        MESSAGE => "This is a dbg env.",
        URL => "www.my-dbg-url.org",
    },
    PRODUCTION => {
        MESSAGE => "This is a prod env.",
        URL => "www.shinyprodurl.org",
    },
);

sub import {
    my $pkg = shift;
    my ($env) = @_;

    if ( defined $env ) {
        unless ( $env eq 'PRODUCTION'
                or $env eq 'DEBUG' ) {
            croak "Invalid environment '$env'";
        }
        $gEnvironment = $env;
    }
    $gMessage = $gConfig{$gEnvironment}{MESSAGE};
    return;
}

sub Message {
    ($gMessage) = @_ if @_;
    return $gMessage;
}

sub Url {
    return $gConfig{$gEnvironment}{URL};
}


1;

而且，使用它：

#!/usr/bin/perl

use strict; use warnings;

use Cfg qw( PRODUCTION );

print Cfg::Message,"\n";
Cfg::Message("I'm a surcharged message.");

print Cfg::Message;

是否可以将参数传递给Perl模块加载？

2 个答案: