Question

我正在尝试运行For Next循环，直到特定列的最后一行（但不是表单的最后一行）。所以我的列表的第一部分在F列中有数据而第二部分没有。我只想将宏应用于第一部分。由于某种原因，循环只使用某些命令运行第一部分，但不会与我现在尝试执行的操作一起运行。（我知道手动分离这两个零件然后再运行它会很容易，但它让我疯了，不知道我做错了什么：））。

这是代码：

Dim i As Integer
Dim g As Double
g = 0.083333333
Dim lastrow As Long
lastrow = Sheets("zm").Range("f" & Rows.Count).End(xlUp).Row

Sheets("zm").Activate

For i = 2 To lastrow

    If Sheets("zm").Cells(i, 1) = Sheets("zm").Cells(i + 1, 1) And Sheets("zm").Cells(i, 5) = Sheets("zm").Cells(i + 1, 5) And Sheets("zm").Cells(i + 1, 6) - Sheets("zm").Cells(i, 7) < g Then
        Sheets("zm").Cells(i + 1, 7).Copy
        Sheets("zm").Cells(i, 7).Select
        ActiveSheet.Paste
        Application.CutCopyMode = False
        Sheets("zm").Rows(i + 1).Delete
    End If

Next i

感谢您的帮助！

Answer 1

避免Select / Selection和/或Activate / ActiveXXX

试试这个：

Option Explicit

Sub main()
    Dim i As Long, lastrow As Long
    Dim g As Double
    g = 0.083333333

    With Worksheets("zm")
        lastrow = .Cells(.Rows.Count, "F").End(xlUp).Row

        For i = lastrow To 2 Step -1
            If .Cells(i, 1) = .Cells(i + 1, 1) And .Cells(i, 5) = .Cells(i + 1, 5) And .Cells(i + 1, 6) - .Cells(i, 7) < g Then
                .Cells(i + 1, 7).Copy Destination:=.Cells(i, 7)
                .Rows(i + 1).Delete
            End If
        Next i
    End With
End Sub

VBA用于下一个循环，直到列的最后一行，但不是最后一行工作表

1 个答案: