Question

请建议如何在tokenize中获取前面的文字。在此示例中，将应用基于先前文本的Web属性。例如，如果'SKY1996'类型文本以字符串'Moon'开头，则属性值为'Moon'，否则为'Sun'。

XML：

<article>
 <text1>The solar eclipse Sun: SKY1996 is happenned in 1996</text1>
 <text2>The moon eclipse Moon: SKY1997 is happenned in 1997</text2>
</article>

XSLT 2.0：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="@*|node()">
        <xsl:copy><xsl:apply-templates select="@*|node()"/></xsl:copy>
    </xsl:template>

    <xsl:template match="text1/text()|text2/text()">
        <xsl:for-each select="tokenize(., ' ')">
            <xsl:variable name="varPrecededText"><xsl:value-of select=".[preceding-sibling::node()[1]]"/></xsl:variable><!--Within tokenize, preceded text value --><!--Requesting suggestion to get this -->
            <xsl:choose>
                <xsl:when test="matches(., '^([S][K][Y])\d{4}$')">
                    <xsl:element name="web">
                        <xsl:attribute name="href">
                            <xsl:choose>
                                <xsl:when test="contains($varPrecededText, 'Moon')">
                                    <xsl:text>MoonEclipse:</xsl:text>
                                </xsl:when>
                                <xsl:otherwise><xsl:text>SunEclipse:</xsl:text></xsl:otherwise>
                            </xsl:choose>
                            <xsl:value-of select="."/>
                        </xsl:attribute>
                        <xsl:value-of select="."/>
                    </xsl:element><xsl:if test="not(position()=last())"><xsl:text> </xsl:text></xsl:if>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="."/>
                    <xsl:if test="not(position()=last())"><xsl:text> </xsl:text></xsl:if>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </xsl:template>

必填结果：

<article>
<text1>The solar eclipse Sun: <web href="SunEclipse:SKY1996">SKY1996</web> is happenned in 1996</text1>
<text2>The moon eclipse Moon: <web href="MoonEclipse:SKY1997">SKY1997</web> is happenned in 1997</text2>
</article>

Answer 1

我只想使用analyze-string：

<xsl:template match="text1/text()|text2/text()">
    <xsl:analyze-string select="." regex="((\w+):)\s+([S][K][Y]\d{{4}})">
        <xsl:matching-substring>
            <web href="{regex-group(2)}Eclipse:{regex-group(3)}">
                <xsl:value-of select="regex-group(3)"/>
            </web>
        </xsl:matching-substring>
        <xsl:non-matching-substring>
            <xsl:value-of select="."/>
        </xsl:non-matching-substring>
    </xsl:analyze-string>
</xsl:template>

((\w+):)\s+([S][K][Y]\d{{4}})在第2组中抓取Sun: SKY1996和Moon: SKY1997，Sun和Moon，在第3组中抓取SKY1996和SKY1997这些匹配在 xsl：matching-substring 中处理，以用所需的结构替换它们。不匹配保持原样。

在xsl tokenize中，如何获取前面的文本值

1 个答案: