Question

我在 Moonscript Lua 中写了一个简单的Lisp解释器。 评估程序如下所示：

eval = ( env, expr ) ->
    if is_symbol expr
        lookup env, expr
    elseif is_define expr 
        eval_define env, expr
    elseif is_lambda expr 
        eval_lambda env, expr
    else call (map (partial eval, env), expr)

工作正常。但现在我真的想以一种看起来像这样的方式来追踪这个过程：

(+ (+ a b) (+ a c))

(+ (+ 1 2) (+ 1 4))

(+ 3 5)

8

问题是，由于评估过程是递归的，所以我没有打印出整个表达式。

我是否必须以命令式的方式重写评估者，或者我错过了一些明显的东西？

Answer 1

这个答案是使用Common Lisp，因为我真的不认识Lua。

实际跟踪

通常，您希望跟踪代码中实际发生的情况。以下是对函数的重写以及跟踪工具可以执行的操作的示例：

(defun normal-eval (form env)
  (etypecase form
    (cons (destructuring-bind (op . args) form
            (apply op
                   (mapcar (lambda (u)
                             (normal-eval u env))
                           args))))
    (null nil)
    (symbol (cdr (assoc form env)))
    (t form)))

> (trace normal-eval)
> (normal-eval '(+ (+ 1 3 a) 2) '((a . 5)))

0: (NORMAL-EVAL (+ (+ 1 3 A) 2) ((A . 5)))
  1: (NORMAL-EVAL (+ 1 3 A) ((A . 5)))
    2: (NORMAL-EVAL 1 ((A . 5)))
    2: NORMAL-EVAL returned 1
    2: (NORMAL-EVAL 3 ((A . 5)))
    2: NORMAL-EVAL returned 3
    2: (NORMAL-EVAL A ((A . 5)))
    2: NORMAL-EVAL returned 5
  1: NORMAL-EVAL returned 9
  1: (NORMAL-EVAL 2 ((A . 5)))
  1: NORMAL-EVAL returned 2
0: NORMAL-EVAL returned 11

期望的痕迹

据我所知，没有简单的方法可以使用您提供的代码获得所需的输出。但是，如果您愿意更改代码，只需逐步重写术语，即可以纯函数的方式获得所需的跟踪。但是，您必须阻止评估已评估的术语，以便逐渐更改表单。

(defun s-eval (x env)
  (etypecase x
    (cons (destructuring-bind (new-list . some-evalp)
              (reduce
               (lambda (element R)
                 (destructuring-bind (rec-list . some-evalp) R
                   (multiple-value-bind (value evalp) (s-eval element env)
                     (cons (list* value rec-list)
                           (or some-evalp evalp)))))
               (rest x)
               :from-end t
               :initial-value (cons nil nil))
            (values
             (if some-evalp
                 ;; a least one element required some work
                 ;; so we return the modified term. 
                 (cons (first x) new-list)
                 ;; all elements are literal, we can actually
                 ;; replace this form by its evaluation
                 (apply (first x) new-list))
             T)))
    (null (values nil nil))
    (symbol (values (cdr (assoc x env)) t))
    (t (values x nil))))

(defun step-eval (form &optional env)
  (print form)
  (multiple-value-bind (value evalp)
      (s-eval form env)
    (if evalp
        (step-eval value env)
        value)))

> (step-eval '(+ (+ 1 3 a) 2) '((a . 5)))


(+ (+ 1 3 A) 2) 
(+ (+ 1 3 5) 2) 
(+ 9 2) 
11


> (step-eval '(+ (+ 1 3 a) (* b a)) '((a . 5) (b . 0)))


(+ (+ 1 3 A) (* B A)) 
(+ (+ 1 3 5) (* 0 5)) 
(+ 9 0) 
9

> (step-eval '(+ (+ a b) (+ a c)) '((a . 1)
                                  (b . 2)
                                  (c . 4)))


(+ (+ A B) (+ A C)) 
(+ (+ 1 2) (+ 1 4)) 
(+ 3 5) 
8

S-EVAL评估环境中的表单并返回两个值：表单的评估和一个布尔值，指示某些评估实际是否已发生或者该术语是否为自我评估（a文字）。此布尔值用于防止转换通过递归评估转换子项的术语。 STEP-EVAL打印表单并调用S-EVAL，然后递归调用自己，直到评估终止。

跟踪递归计算器

1 个答案:

实际跟踪

期望的痕迹