Question

我有以下XML结构：

<node name="A">
  <node name="B">
    <node name="C"/>
    <node name="D"/>
    <node name="E"/>
  </node>
  <node name="D"/>
  <node name="E"/>
</node>

我需要获取所有叶子节点。我使用// node [not（node）]来获取它们。现在我需要通过保留层次结构更深层的元素来删除重复项。我该怎么做？

Answer 1

此转化：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="vallLeaves" select="//node()[not(node())]"/>

 <xsl:template match="/">
$vallLeaves:
     <xsl:copy-of select="$vallLeaves"/>

$vallDistinctLeaves:    
     <xsl:for-each select="$vallLeaves">
       <xsl:if test=
       "generate-id()
        =
         generate-id($vallLeaves[@name
                                =
                                 current()/@name
                               ]
                                  [1]
                   )
     ">
         <xsl:copy-of select="."/>
       </xsl:if>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档：

<node name="A">
  <node name="B">
    <node name="C"/>
    <node name="D"/>
    <node name="E"/>
  </node>
  <node name="D"/>
  <node name="E"/>
</node>

生成想要的正确结果：

$vallLeaves:
     <node name="C"/>
<node name="D"/>
<node name="E"/>
<node name="D"/>
<node name="E"/>

$vallDistinctLeaves:    
     <node name="C"/>
<node name="D"/>
<node name="E"/>

<强> II。 XSLT 2.0解决方案：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="vallLeaves" select="//node()[not(node())]"/>
    <xsl:variable name="vallDistinctLeaves" as="element()*">
      <xsl:for-each-group select="$vallLeaves" group-by="@name">
       <xsl:sequence select="."/>
      </xsl:for-each-group>
    </xsl:variable>

 <xsl:template match="/">
$vallLeaves:
     <xsl:sequence select="$vallLeaves"/>

$vallDistinctLeaves:    
     <xsl:sequence select="$vallDistinctLeaves"/>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于同一XML文档（上图）时，会生成相同的正确结果：

$vallLeaves:
     <node name="C"/>
<node name="D"/>
<node name="E"/>
<node name="D"/>
<node name="E"/>

$vallDistinctLeaves:    
     <node name="C"/>
<node name="D"/>
<node name="E"/>

如何根据层次结构中的级别删除重复项？

1 个答案: