Question

如何查询维基数据以获取标签中包含单词的所有项目？我试过这个，但没有工作;没有找到任何东西。

SELECT ?item ?itemLabel WHERE {
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en".
    ?item rdfs:label ?itemLabel.  
  }
FILTER(CONTAINS(LCASE(?itemLabel), "keyword"))
}
LIMIT 1000

Answer 1

根据您的问题和提供的有用评论，我最终得到了这个查询

SELECT ?item ?itemLabel
WHERE { 
  ?item rdfs:label ?itemLabel. 
  FILTER(CONTAINS(LCASE(?itemLabel), "city"@en)). 
} limit 10

我得到了那些结果

item          itemLabel
wd:Q515       city
wd:Q7930989   city
wd:Q15253706  city
wd:Q532039    The Eternal City
wd:Q1969820   The Eternal City
wd:Q3986838   The Eternal City
wd:Q7732543   The Eternal City
wd:Q7737016   The Golden City
wd:Q5119      capital city
wd:Q1555      Guatemala City

try it here

Answer 2

是的，您可以按标签搜索，例如：

SELECT distinct ?item ?itemLabel ?itemDescription WHERE{  
  ?item ?label "Something"@en.  
  ?article schema:about ?item .
  ?article schema:inLanguage "en" .
  ?article schema:isPartOf <https://en.wikipedia.org/>. 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }    
}

在Query page上查看。

Answer 3

截至今天（2020年6月），最好的方法似乎是使用这些CirrusSearch扩展。以下代码在所有英文标签中进行子字符串搜索，并在<20秒内返回10,000个结果。我相信它还会搜索别名和描述。

SELECT DISTINCT ?item ?label
WHERE
{
  SERVICE wikibase:mwapi
  {
    bd:serviceParam wikibase:endpoint "www.wikidata.org";
                    wikibase:api "Generator";
                    mwapi:generator "search";
                    mwapi:gsrsearch "inlabel:city"@en;
                    mwapi:gsrlimit "max".
    ?item wikibase:apiOutputItem mwapi:title.
  }
  ?item rdfs:label ?label. FILTER( LANG(?label)="en" )

}

Answer 4

如上所述，在SPARQL查询服务中，不区分大小写和截断的查询非常慢。我在github上找到了这个项目：https://github.com/inventaire/entities-search-engine 它设置了一个ElasticSearch索引，该索引允许快速查询诸如自动完成之类的用例。

如何使用其标签查询Wikidata项目？

4 个答案: