Question

我刚刚开始使用CUDA。现在我有一个问题。我有N * N矩阵，窗口比例是8x8。我想将这个矩阵细分为多个子矩阵并找到它的最大值。例如，如果我有64 * 64矩阵，那么我将有8个8 * 8比例的小矩阵，并找出8个最大值。最后，我将所有最大值保存到新数组中，但其顺序始终会更改。我想找到解决方案以保持正确的顺序

__global__ void calculate_emax_kernel(float emap[],float emax[], int img_height, int img_width,int windows_size)
{
    int x_index = blockIdx.x*blockDim.x+threadIdx.x;
    int y_index = blockIdx.y*blockDim.y+threadIdx.y;

    int num_row_block = img_height/windows_size;
    int num_col_block = img_width/windows_size;
    __shared__ float window_elements[256];
    __shared__ int counter;
    __shared__ int emax_count;

    if (threadIdx.x == 0) emax_count = 0;
    __syncthreads();
    int index;
    int emax_idx = 0;


    if(y_index >= img_height|| x_index >= img_width) return;
    for(int i = 0; i < num_row_block; i++)
    {
        for(int j = 0; j < num_col_block; j++)
        {
            counter = 0;
            if(y_index >= i*windows_size && y_index < (i+1)*windows_size
                    && x_index >= j*windows_size && x_index < (j+1)*windows_size)
            {
                int idx = y_index*img_height + x_index;
                index = atomicAdd(&counter, 1);

                window_elements[index] = emap[idx];
                __syncthreads();


                // reduction
                unsigned int k = (windows_size*windows_size)/2;
                while(k != 0)
                {
                    if(index < k)
                    {
                        window_elements[index] = fmaxf(window_elements[index], window_elements[index+k]);

                    }
                    k /= 2;
                }
                if(index == 0)
                {
                    emax[i*num_row_block+j] = window_elements[index];
                }
            }
            __syncthreads();
        }
        __syncthreads();
    }
    __syncthreads();
}

这是我的配置

void construct_emax(float *input,float *output, int img_height, int img_width)
{
    int windows_size = 4;
    float * d_input, * d_output;
    cudaMalloc(&d_input, img_width*img_height*sizeof(float));
    cudaMalloc(&d_output, img_width*img_height*sizeof(float));

    cudaMemcpy(d_input, input, img_width*img_height*sizeof(float), cudaMemcpyHostToDevice);
    dim3 blocksize(16,16);
    dim3 gridsize;

    gridsize.x=(img_width+blocksize.x-1)/blocksize.x;
    gridsize.y=(img_height+blocksize.y-1)/blocksize.y;

    calculate_emax_kernel<<<gridsize,blocksize>>>(d_input,d_output,img_height,img_width,windows_size);

}

Answer 1

使用CUDA，parallel reduction很棘手; segmented parallel reduction比较棘手。现在你在2-D中进行，你的段/窗口小于线程块。

对于大窗口尺寸，我不认为这是一个问题。您可以使用一个线程块来减少一个窗口。例如，如果您有一个16x16窗口，则可以简单地使用16x16线程块。如果您有更大的窗口大小，例如64x64，您仍然可以使用16x16线程块。首先在数据加载期间将64x64窗口缩小为16x16元素，然后在线程块内减少到1个标量。

对于小于块大小的窗口大小，您必须为每个线程块减少多个窗口以获得更高的性能。您可以使用当前的块/网格配置，其中每个256线程块（16x16）负责16个4x4窗口。但这并不是最佳选择，因为每个32线程包装都由两部分组成（2x16）。这对于coalesced global memory access来说并不好，并且很难将2x16扭曲映射到一个或多个4x4窗口以进行有效的并行缩减。

或者我建议你使用256线程的1-D线程块。每个m个线程都会减少一个m x m窗口。然后你可以使用二维网格覆盖整个图像。

const int m = window_size;
dim3 blocksize(256);
dim3 gridsize((img_width+255)/256, (img_height+m-1)/m);

在核心功能中，你可以

在全局数据加载期间将每个m x m窗口缩小为1x m向量;
使用树缩减方法将1x m向量减少为标量。

以下代码是一个概念演示，当m是2和m <= 32的幂时，它会起作用。您可以进一步修改它以进行任意m和更好的边界检查。

#include <assert.h>
#include <cuda.h>
#include <thrust/device_vector.h>

__global__ void calculate_emax_kernel(const float* input, float* output,
                                      int height, int width, int win_size,
                                      int out_width) {
  const int tid = threadIdx.x;
  const int i = blockIdx.y * win_size;
  const int j = blockIdx.x * 256 + tid;
  const int win_id = j % win_size;

  __shared__ float smax[256];

  float tmax = -1e20;
  if (j < width) {
    for (int tile = 0; tile < win_size; tile++) {
      if (i + tile < height) {
        tmax = max(tmax, input[(i + tile) * width + j]);
      }
    }
  }
  smax[tid] = tmax;
  for (int shift = win_size / 2; shift > 0; shift /= 2) {
    if (win_id < shift) {
      smax[tid] = max(smax[tid], smax[tid + shift]);
    }
  }
  if (win_id == 0 && j < width) {
    output[blockIdx.y * out_width + (j / win_size)] = smax[tid];
  }
}

int main() {
  const int height = 1024;
  const int width = 1024;
  const int m = 4;
  thrust::device_vector<float> in(height * width);
  thrust::device_vector<float> out(
      ((height + m - 1) / m) * ((width + m - 1) / m));

  dim3 blocksize(256);
  dim3 gridsize((width + 255) / 256, (height + m - 1) / m);

  assert(m == 2 || m == 4 || m == 8 || m == 16 || m == 32);
  calculate_emax_kernel<<<gridsize, blocksize>>>(
      thrust::raw_pointer_cast(in.data()),
      thrust::raw_pointer_cast(out.data()),
      height, width, m, (width + m - 1) / m);

  return 0;
}

Answer 2

如果您愿意使用一个库，则可以使用一些指针：

使用NPP，一组原语（来自nvidia） https://docs.nvidia.com/cuda/npp/group__image__filter__max.html
一个较低级的库，用于其他减少操作和使用硬件的方式更精细（来自nvidia / nvlabs） http://nvlabs.github.io/cub/

在CUDA中查找矩阵的最大值

2 个答案: