当我发现如果我没有将目标文件与gcc链接到标准库时，我发现我的应用程序变成了僵尸，我正在试验汇编代码和GTK + 3库。这是我的stdlib - 免费应用程序
%include "gtk.inc"
%include "glib.inc"
global _start
SECTION .data
destroy db "destroy", 0 ; const gchar*
strWindow db "Window", 0 ; const gchar*
SECTION .bss
window resq 1 ; GtkWindow *
SECTION .text
_start:
; gtk_init (&argc, &argv);
xor rdi, rdi
xor rsi, rsi
call gtk_init
; window = gtk_window_new (GTK_WINDOW_TOPLEVEL);
xor rdi, rdi
call gtk_window_new
mov [window], rax
; gtk_window_set_title (GTK_WINDOW (window), "Window");
mov rdi, rax
mov rsi, strWindow
call gtk_window_set_title
; g_signal_connect (window, "destroy", G_CALLBACK (gtk_main_quit), NULL);
mov rdi, [window]
mov rsi, destroy
mov rdx, gtk_main_quit
xor rcx, rcx
xor r8, r8
xor r9, r9
call g_signal_connect_data
; gtk_widget_show (window);
mov rdi, [window]
call gtk_widget_show
; gtk_main ();
call gtk_main
mov rax, 60 ; SYS_EXIT
xor rdi, rdi
syscall
以下是与标准库链接相同的代码
%include "gtk.inc"
%include "glib.inc"
global main
SECTION .data
destroy db "destroy", 0 ; const gchar*
strWindow db "Window", 0 ; const gchar*
SECTION .bss
window resq 1 ; GtkWindow *
SECTION .text
main:
push rbp
mov rbp, rsp
; gtk_init (&argc, &argv);
xor rdi, rdi
xor rsi, rsi
call gtk_init
; window = gtk_window_new (GTK_WINDOW_TOPLEVEL);
xor rdi, rdi
call gtk_window_new
mov [window], rax
; gtk_window_set_title (GTK_WINDOW (window), "Window");
mov rdi, rax
mov rsi, strWindow
call gtk_window_set_title
; g_signal_connect (window, "destroy", G_CALLBACK (gtk_main_quit), NULL);
mov rdi, [window]
mov rsi, destroy
mov rdx, gtk_main_quit
xor rcx, rcx
xor r8, r8
xor r9, r9
call g_signal_connect_data
; gtk_widget_show (window);
mov rdi, [window]
call gtk_widget_show
; gtk_main ();
call gtk_main
pop rbp
ret
两个应用程序都会创建GtkWindow。但是，当窗口关闭时，两者表现不同。前者导致僵尸进程，我需要按Ctrl+C。后者表现出预期的行为，即一旦窗口关闭，应用程序就会终止。
我的感觉是标准的lib正在执行一些我在第一个代码示例中忽略的基本操作，但我不知道它是什么。
所以我的问题是：第一个代码示例中缺少什么？
答案 0 :(得分：3)
感谢@MichaelPetch这个想法，它完美地解释了所有观察到的症状：
如果gtk_main在返回时保留任何线程运行，则两个程序之间最重要的区别是eax=60 / syscall仅退出当前线程。请参阅_exit(2) man page中的文档，其中指出glibc的_exit()包装函数自glibc2.3起已使用exit_group。
exit_group(2)为eax=231 / syscall。这是main()返回时CRT启动/清理代码运行的内容。
您可以在两个版本上使用strace ./a.out来查看此内容。
这至少让我感到惊讶：初始线程退出但其他线程仍在运行的进程显示为僵尸。我在自己的桌面上试了一下（请参阅本答案的结尾，以获取构建命令和外部声明，因此您不需要gtk.inc），而且您确实得到了一个报告为zombie，但你可以ctrl-c来杀死gtk在gtk_main返回时运行的其他线程。
./thread-exit & # or in the foreground, and do the following commands in another shell
[1] 20592
$ ps m -LF -p $(pidof thread-exit)
UID PID PPID LWP C NLWP SZ RSS PSR STIME TTY STAT TIME CMD
peter 20592 7749 - 0 3 109031 21920 - 06:28 pts/12 - 0:00 ./thread-exit
peter - - 20592 0 - - - 0 06:28 - Sl 0:00 -
peter - - 20593 0 - - - 0 06:28 - Sl 0:00 -
peter - - 20594 0 - - - 0 06:28 - Sl 0:00 -
然后关闭窗口：进程没有退出，仍有两个线程正在运行+ 1个僵尸。
$ ps m -LF -p $(pidof thread-exit)
UID PID PPID LWP C NLWP SZ RSS PSR STIME TTY STAT TIME CMD
peter 20592 7749 - 0 3 0 0 - 06:28 pts/12 - 0:00 [thread-exit] <defunct>
peter - - 20592 0 - - - 0 06:28 - Zl 0:00 -
peter - - 20593 0 - - - 0 06:28 - Sl 0:00 -
peter - - 20594 0 - - - 0 06:28 - Sl 0:00 -
我不确定ps m -LF是否是最好的命令，但似乎有效。它表示关闭窗口后只有主线程退出，其他2个线程仍在运行。您甚至可以直接查看/proc/$(pidof thread-exit)/task，而不是使用ps为您执行此操作。
re：关于不想链接libc的评论：
避免glibc的CRT启动/清理（通过定义_start而不是_main）与避免libc是一回事。您的代码不会直接调用任何libc函数，但libgtk会这样做。 ldd /usr/lib/x86_64-linux-gnu/libgtk-3.so.0表明libgtk依赖于libc，因此动态链接器无论如何都会将libc映射到您的进程中。实际上，ldd在您自己的程序中表示，即使您没有直接将-lc放在链接器命令行上。
因此，您可以直接链接libc并从_start致电exit(3)。
旁注：定义main的版本不需要使用rbp制作堆栈框架。
如果遗漏push rbp / mov rbp, rsp，您仍需要做一些事情来在call之前对齐堆栈，但它可以是push rax，或者仍然是push rbp如果你想混淆。所以：
main:
push rax ; align the stack
...
call gtk_widget_show
pop rax ; restore stack to function-entry state
jmp gtk_main ; optimized tail-call
如果你想保留帧指针的东西，你仍然可以进行尾调用，但是pop rbp / jmp gtk_main。
PS：对于那些想要自己尝试的人来说，这个改变可以让你构建它而无需去寻找gtk.inc：
;%include "gtk.inc"
;%include "glib.inc"
extern gtk_init
extern gtk_window_new
extern g_signal_connect_data
extern gtk_window_set_title
extern gtk_widget_show
extern gtk_main
extern gtk_main_quit
构建：
yasm -felf64 -Worphan-labels -gdwarf2 thread-exit.asm &&
gcc -nostdlib -o thread-exit thread-exit.o $(pkg-config --libs gtk+-3.0)