Question

前言：我目前正在学习一门在LISP中教授的精简课程，我从未在生活中与LISP合作过，因此我必须在周末学习这门语言。我提前为糟糕的代码道歉。我对LISP的语法非常熟悉，以使代码正常工作，而不是更多。

我目前正在开发一个解决地图着色问题的程序。该代码采用一个序列，其中每个子序列的第一个元素是一个状态，第二个元素代表一种颜色。 ex：'（（A R）（B G）（C G）（D Y）（E B）（F B））然后检查以确保没有状态与其约束的状态（由约束列表定义）具有相同的颜色。我知道可能有很多更简洁的方法可以做到这一点，但我目前正在努力的是，只要满足if语句，我的dolist循环立即返回值T.到目前为止，我一直无法让函数简单地返回一个值，并且不得不求助于这个将变量设置为true并等待循环完成以使代码工作的非常丑陋/错误的方法。我已经尝试过使用return并且在if语句中只有T，但是，在这两种情况下，循环都会完成而不是返回一个值，我不知道为什么。

(setq constraint '((A (B C E)) (B (A E F)) (C (A E F)) (D (F)) (E (A B C F)) (F (B C D E))))

(defun check_constraint (f s)
    (setf ans nil)
    (dolist (state constraint)
        (if (eq (first state) f)
            (if (search (list s) (second state))
                (setf ans T) ;;where I want it to just return T
            )
        )
    )
    ans
)

;;ex: ((A R) (B R)  (C B)  (D R)  (E B)  (F G))
(defun check_conflict (lst)
    (setf anb nil)
    (dolist (state lst)
        (dolist (neighbor (remove state lst))
            (if (check_constraint (first state) (first neighbor))
                (if (eq (second state) (second neighbor))
                    (setf anb T)) ;;where I want it to just return T
            )
        )
    )
    anb
)

编辑：我最后只是用递归来解决这个问题。代码现在更干净但我仍然想知道我的问题是什么。这是递归代码。

(setq constraint '((A (B C E)) (B (A E F)) (C (A E F)) (D (F)) (E (A B C F)) (F (B C D E))))

(defun check_constraint (lst f s)
    (COND
        ((null lst) nil)
        ((search (list (car (car lst))) f)
            (if (search s (second (car lst))) T))
        (t (check_constraint (cdr lst) f s))
    )
)

(defun check_neighbor (check lst)
    (COND
        ((null lst) nil)
        ((check_constraint constraint (list (car check)) (list (first (first lst))))
            (if (eq (second check) (second (car lst))) T))
        (t (check_neighbor check (cdr lst)))
    )
)

;;(check_state '((A R) (B R) (C B) (D R) (E B) (F G)))
(defun check_state (lst)
    (COND
        ((null lst) nil)
        ((check_neighbor (car lst) (cdr lst)) T)
        (t (check_state (cdr lst)))
    )
)

Answer 1

首先是一些风格问题。您应该使用DEFVAR or DEFPARAMETER来声明全局变量。这些也应该在名称周围用星号表示它们是全局的（或者实际上是特殊的）。

(defparameter *constraint*
  '((A (B C E))
    (B (A E F))
    (C (A E F))
    (D (F))
    (E (A B C F))
    (F (B C D E))))

用于命名事物的lisp约定是在单词之间使用破折号（CHECK-CONSTRAINT而不是CHECK_CONSTRAINT）。您还应该更喜欢变量名称的完整单词而不是缩写（LIST而不是LST）。结束括号不应该写在自己的行上。

那么实际的问题。您可以使用RETURN从名为NIL的块中返回值。循环建立这样一个块，所以你可以编写第一个函数，如

(defun check-constraint (first second)
  (dolist (state *constraint*)
    (when (and (eq first (first state))
               (member second (second state)))
      (return t))))

当只有当时的分支时，最好使用WHEN代替IF。我还使用IF将两个AND合并为一个。由于您将S打包到列表中以使用SEARCH，我认为您可能希望使用MEMBER代替（虽然我不确定，因为我并不完全相同知道代码应该做什么）。如果错误，你可以改回来。

您可能还可以将其简化为

(defun check-constraint (first second)
  (member second (second (find first *constraint* :key #'first))))

在第二个功能中，您有两个循环。如果使用RETURN从内部返回，则最后继续外部循环并忽略返回值。所以你必须使用RETURN-FROM从函数而不是内循环返回。

(defun check-conflict (list)
  (dolist (state list)
    (dolist (neighbor (remove state list))
      (when (and (check-constraint (first state) (first neighbor))
                 (eq (second state) (second neighbor)))
        (return-from check-conflict t)))))

通用LISP（SBCL）：从循环内返回值

1 个答案: