Question

我已经关注了xml：

<?xml version="1.0" encoding="UTF-8"?>
<DATA>
    <CUSTOMER>
        <phonenumber>+0002443333</phonenumber>
        <email>blabla@blabla.com</email>
        <category>36465194</category>
        <segment>SB</segment>
    </CUSTOMER>
</DATA>

我需要选择最深的元素+它的父元素并从中创建新的文件名并复制这个最深元素的数据+周围的xml结构。

因此，例如，文件CUSTOMER_phonenumber.xml将包含

<?xml version="1.0" encoding="UTF-8"?>
<DATA>
    <CUSTOMER>
        <phonenumber>+0002443333</phonenumber>
    </CUSTOMER>
</DATA>

目前我有以下xslt

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="DATA/*">
        <xsl:for-each select="descendant::*[not(*)]">
            <xsl:variable name="parentTag">
                <xsl:value-of select="name(..)"/>
            </xsl:variable>
            <xsl:variable name="currentTag">
                <xsl:value-of select="name()"/>
            </xsl:variable>
            <xsl:result-document method="xml" href="{$parentTag}_{$currentTag}.xml" indent="yes">
                <xsl:copy-of select="ancestor::*[@currentTag]"/>
                <xsl:copy-of select="."/>
            </xsl:result-document>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

我可以成功创建输出文件并将最深层的元素放在那里，但我不知道如何复制结构。

那么如何只用它的结构复制一个元素？

由于

Answer 1

您可以选择祖先并处理它们，在单一模式样式表中执行以下操作：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0">

    <xsl:output indent="yes"/>

    <xsl:template match="/">
        <xsl:for-each select="//*[not(*)]">
            <xsl:result-document href="test2016071403Result{position()}.xml">
                <xsl:apply-templates select="ancestor-or-self::*[last()]">
                    <xsl:with-param name="tree" select="ancestor-or-self::*"/>
                </xsl:apply-templates>
            </xsl:result-document>
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="*">
        <xsl:param name="tree"/>
        <xsl:choose>
            <xsl:when test="not($tree[2])">
                <xsl:copy-of select="."></xsl:copy-of>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy>
                    <xsl:copy-of select="@*"/>
                    <xsl:apply-templates select="$tree[2]">
                        <xsl:with-param name="tree" select="$tree[position() gt 1]"/>
                    </xsl:apply-templates>
                </xsl:copy>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

如果您还想将默认模式用于其他处理/输出，则使用其他模式，例如

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0">

    <xsl:output indent="yes"/>

    <xsl:template match="/">
        <xsl:for-each select="//*[not(*)]">
            <xsl:result-document href="test2016071403Result{position()}.xml">
                <xsl:apply-templates select="ancestor-or-self::*[last()]" mode="tree">
                    <xsl:with-param name="tree" select="ancestor-or-self::*"/>
                </xsl:apply-templates>
            </xsl:result-document>
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="*" mode="tree">
        <xsl:param name="tree"/>
        <xsl:choose>
            <xsl:when test="not($tree[2])">
                <xsl:copy-of select="."></xsl:copy-of>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy>
                    <xsl:copy-of select="@*"/>
                    <xsl:apply-templates select="$tree[2]" mode="tree">
                        <xsl:with-param name="tree" select="$tree[position() gt 1]"/>
                    </xsl:apply-templates>
                </xsl:copy>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

由于你的命名方案href="{$parentTag}_{$currentTag}.xml"会导致问题，如果有两个相同名称的元素我没有使用过，但当然上面的确允许你使用你的命名方案，如果你确定可以有没有相同名称的元素。

xslt将最深的节点复制到文件

1 个答案: