Question

我有一些看起来像这样的文件：

<p>It is a <noun>truth</noun> <adverb>universally</adverb
<verb>acknowledged<verb>, that a <adjective>single</adjective>
<noun>man</noun> in <noun>possession<noun> of a 
<adjective>good</adjective> <noun>fortune</noun>, 
<verb>must</verb> <verb>be</verb> in want of a <noun>wife</noun>.</p>

（除了数百页长并且有更多元素名称）

我想使用XSLT输出html文件，每个文件显示包含特定元素的每个段落并突出显示该元素。因此，上面的段落可能会在每个输出文件中结束，但在一个中，动词将突出显示，而在另一个中，名词将突出显示。它根本不会出现在＆＃34;连词＆＃34;文件，因为它不包含该元素。

对于已命名的元素，我一直在使用此代码：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">      
        <xsl:result-document method="html" href="nouns.html">
            <html>
                <body>
                    <xsl:for-each select="collection('index.xml')//p[.//noun]">
                        <p>
                            <xsl:apply-templates select="."/>
                        </p>
                    </xsl:for-each>
                </body>
            </html>
        </xsl:result-document>
</xsl:template>

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="noun">
    <span class="highlight">
        <xsl:apply-templates select="@*|node()"/>
    </span>
</xsl:template>

（在这种情况下，还有其他模板与其他元素匹配，以设置斜体/上标样式等）

这非常有效，但我需要一种方法来自动为很长的元素列表生成单独的文档。我有一个单独的文档列出了这些元素及其关联：

<speechParts>
  <speechPart><name>Nouns</name><tagName>noun</tagName></speechPart>
  <speechPart><name>Verbs</name><tagName>verb</tagName></speechPart>
  ...
</speechParts>

我已尝试通过将以下样式表应用于上面的列表来生成我需要的所有文件：

<xsl:template match="/">   
  <xsl:for-each select="speechParts/speechPart">
        <xsl:result-document method="html" href="{name}.html">
            <html>
                <body>
                    <xsl:for-each select="collection('index.xml')
                       //p[.//*[name()=current()/elName]]">
                        <p>
                            <xsl:apply-templates select="."/>
                        </p>
                    </xsl:for-each>
                </body>
            </html>
        </xsl:result-document>
</xsl:template>

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[name()=current()/elName]">
    <span class="highlight">
        <xsl:apply-templates select="@*|node()"/>
    </span>
</xsl:template>

这不起作用，因为模板不知道＆＃39; elName＆＃39;的当前值是什么？是的，我想。我用变量玩了很多年，但我不认为XSLT会让我使用变量或参数作为匹配模式。

看起来这不应该像我做的那样复杂......

（这是我昨天问过的一个问题的后续问题。非常感谢你帮助我 - 它真的帮助我学习。）

Answer 1

我建议你按照以下几点尝试：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/">
    <xsl:for-each select="speechParts/speechPart">
        <xsl:variable name="elemName" select="tagName"/>
        <xsl:result-document method="html" href="{name}.html">
            <html>
                <body>
                    <xsl:for-each select="collection('index.xml')//p[.//*[name()=$elemName]]">
                        <p>
                            <xsl:apply-templates>
                                <xsl:with-param name="elemName" select="$elemName" tunnel="yes"/>
                            </xsl:apply-templates>
                        </p>
                    </xsl:for-each>
                </body>
            </html>
        </xsl:result-document>
    </xsl:for-each>
</xsl:template>

<xsl:template match="*">
    <xsl:param name="elemName" tunnel="yes"/>
    <xsl:choose>
        <xsl:when test="name()=$elemName">
            <span class="highlight">
                <xsl:apply-templates/>
            </span>
        </xsl:when>
        <xsl:otherwise>
            <xsl:copy>
                <xsl:apply-templates/>
            </xsl:copy>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

XSLT - 为更改/变量元素设置样式

1 个答案: