Question

我正在尝试为我的应用程序实现一个简单的RestfulController。给定以下域类：

class Test {
    String name
    int someInteger

    static constraints = {
    }
}

及其控制者：

class TestController extends RestfulController<Test>{
    TestController() {
        super(Test)
    }
}

在conf / UrlMappings.groovy中我添加了以下条目：

"/api/$controller?(.${format})?" {
    action = [POST: "save", PUT: "save", GET: "index", DELETE:"error"]
}

"/api/$controller/$id?(.${format})?" {
    action = [POST: "update", PUT: "update", GET: "show", DELETE: "delete"]
}

获取请求工作正常，但当http://localhost:8080/app/api/test.json标头存在时，向Content-Type: application/x-www-form-urlencoded之类的网址发送和放置请求无法按预期响应JSON。而是在持久发送entrie之后渲染show动作视图。

我也尝试使用标题Accept: application/json但没效果。

我该如何解决？

编辑：

进一步调查RestfulController的源文件和有关Content Negotiation的文档部分我通过覆盖替换该行的保存和更新方法来修复它：

request.withFormat {

使用：

withFormat {

是故意还是RestfulController的实施存在缺陷？为什么它会考虑Content-Type标头而不是Accept标头来呈现响应？

Answer 1

如果所有控制器的方法始终可以使用JSON进行响应（当有响应主体时），则可以使用responseFormats来实现此目的：

class TestController extends RestfulController<Test>{

    static responseFormats = ['json']

    TestController() {
        super(Test)
    }

    def customJsonAction() {
        respond Something.get(params.id)
    }

    def someActionThatRendersGsp() {
        render view: 'myGsp', model: [foo: 'bar']
    }
}

这意味着无论客户端发送了哪些标头，参数等，控制器都将始终使用JSON进行响应。

Answer 2

很抱歉花了这么长时间才回复。把一切都搞砸了，我遇到了一些麻烦。非常感谢@Dónal的所有帮助。结束使用以下类来完成这个技巧：

import org.codehaus.groovy.grails.web.servlet.HttpHeaders;
import org.springframework.http.HttpStatus;

import grails.artefact.Artefact;
import grails.rest.RestfulController;
import grails.transaction.Transactional;

@Artefact("Controller")
@Transactional(readOnly = true)
class MyRestfulController<T> extends RestfulController<T> {

    public MyRestfulController(Class<T> resource, boolean readOnly = false) {
        super(resource, readOnly);
    }

    @Override
    @Transactional
    def save() {
        if(handleReadOnly()) {
            return
        }
        T instance = createResource(getParametersToBind())

        instance.validate()
        if (instance.hasErrors()) {
            respond instance.errors, view:'create' // STATUS CODE 422
            return
        }

        instance.save flush:true

        def formatHolder = params.format ? this : request
        formatHolder.withFormat {
            form multipartForm {
                flash.message = message(code: 'default.created.message', args: [message(code: "${resourceName}.label".toString(), default: resourceClassName), instance.id])
                redirect instance
            }
            '*' {
                response.addHeader(HttpHeaders.LOCATION,
                        g.createLink(
                                resource: this.controllerName, action: 'show',id: instance.id, absolute: true,
                                namespace: hasProperty('namespace') ? this.namespace : null ))
                respond instance, [status: HttpStatus.CREATED]
            }
        }
    }

    @Override
    @Transactional
    def update() {
        if(handleReadOnly()) {
            return
        }

        T instance = queryForResource(params.id)
        if (instance == null) {
            notFound()
            return
        }

        instance.properties = getParametersToBind()

        if (instance.hasErrors()) {
            respond instance.errors, view:'edit' // STATUS CODE 422
            return
        }

        instance.save flush:true

        def formatHolder = params.format ? this : request
        formatHolder.withFormat {
            form multipartForm {
                flash.message = message(code: 'default.updated.message', args: [message(code: "${resourceClassName}.label".toString(), default: resourceClassName), instance.id])
                redirect instance
            }
            '*'{
                response.addHeader(HttpHeaders.LOCATION,
                        g.createLink(
                                resource: this.controllerName, action: 'show',id: instance.id, absolute: true,
                                namespace: hasProperty('namespace') ? this.namespace : null ))
                respond instance, [status: HttpStatus.OK]
            }
        }
    }

}

使用def formatHolder = params.format ? this : request然后调用formatHolder.withFormat我现在可以独立于请求格式覆盖响应格式。

它对Accept Header不起作用，但至少它可以工作。

当Content-Type：application / x-www-form-urlencoded标头存在时，Grails RestfulController不响应JSON

2 个答案: