Question

如何在Cython中对内存视图进行排序？是否有内置功能可以做到这一点？现在我必须使用numpy数组，并使用numpy排序，这非常慢。

Answer 1

要跟进我的评论，这里有3个选项（numpy和C和C ++标准库选项）

from libcpp.algorithm cimport sort
from libc.stdlib cimport qsort

import numpy as np

def sort_numpy(double[:] a, kind):
    np.asarray(a).sort(kind=kind)

# needs to be compiled with C++        
def sort_cpp(double[::1] a):
    # a must be c continuous (enforced with [::1])
    sort(&a[0], (&a[0]) + a.shape[0])

# The C version requires a comparator function
# which is a little slower since it requires calling function pointers
# and passing pointers rather than numbers
cdef int cmp_func(const void* a, const void* b) nogil:
    cdef double a_v = (<double*>a)[0]
    cdef double b_v = (<double*>b)[0]
    if a_v < b_v:
        return -1
    elif a_v == b_v:
        return 0
    else:
        return 1

def sort_c(double[:] a):
    # a needn't be C continuous because strides helps
    qsort(&a[0], a.shape[0], a.strides[0], &cmp_func)

您将依赖于您正在使用的C / C ++标准库的结果，因此不会过多地阅读我的结果。对于1000长阵列（排序5000次），我得到：

np quick:  0.11296762199890509
np merge:  0.20624926299933577
np heap:  0.2944786230000318
c++:  0.12071316699984891
c:  0.33728832399901876

即。 numpy版本最快。对于100长阵列，我得到了

np quick:  0.022608489000049303
np merge:  0.023513408999860985
np heap:  0.024136934998750803
c++:  0.008449130998997134
c:  0.01909676999821386

即如果你要对很多小数组进行排序，那么调用numpy排序的开销很大，你应该使用C ++（或者可能是C）。如果你正在对大型数组进行排序，你可能会发现很难打败numpy。

在Cython中对memoryview进行排序

1 个答案: