Question

我的Erlang服务器上有一个函数可以将数据发布到Web服务。此Web服务需要计数器（调用它的次数）。我真的不知道他们为什么需要它，但它至关重要。

出于某些原因，我无法使用外部数据库。所以我需要永久地在服务器上存储一些全局变量。我想过将计数器保存到文件中，每次调用函数时都会提取并递增它。

有更有效的方法来实现我的目标吗？

修改该函数可能同时从许多不同的客户端调用，因此这又增加了另一个问题：如果3个客户端同时调用该函数，则函数将仅增加一次计数器，我将收到错误。如何让函数等待另一个函数完成然后执行？

提前致谢。

Answer 1

如果3个客户端同时调用该函数，函数将只增加一次计数器，我将收到错误。如何让函数等待另一个函数完成然后执行？

我会使用一个用gen_server构建的简单计数器，只能从它访问磁盘上的计数器。使用这样的gen_server可以确保您永远不会获得文件访问竞争条件。

这是让你入门的东西：

-module(file_counter).
-export([start_link/0, start/0, increment/0]).
-behaviour(gen_server).
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

start_link() ->
    gen_server:start_link({local, ?MODULE}, ?MODULE, [], []).

start() ->
    gen_server:start({local, ?MODULE}, ?MODULE, [], []).

increment() ->
    gen_server:call(?MODULE, increment).

init([]) ->
    {ok, "file_counter.txt"}.

handle_call(increment, _From, File) ->
    Counter = case file:read_file(File) of
        {ok, Binary} -> binary_to_integer(Binary);
        {error, enoent} -> 0
    end,
    ok = file:write_file(File, integer_to_binary(Counter + 1)),
    {reply, Counter, File}.

handle_cast(_Req, State) ->
    {noreply, State}.

handle_info(_Info, State) ->
    {noreply, State}.

terminate(_Reason, _State) ->
    ok.

code_change(_OldVsn, State, _Extra) ->
    {ok, State}.

演示：

1> c(file_counter).
{ok,file_counter}
2> file_counter:start_link().
{ok,<0.40.0>}
3> file_counter:increment().
0
4> file_counter:increment().
1
5> file_counter:increment().
2
6> [ spawn_link(file_counter, increment, []) || _ <- lists:seq(1, 9998) ].
[<0.45.0>,<0.46.0>,<0.47.0>,<0.48.0>,<0.49.0>,<0.50.0>,
 <0.51.0>,<0.52.0>,<0.53.0>,<0.54.0>,<0.55.0>,<0.56.0>,
 <0.57.0>,<0.58.0>,<0.59.0>,<0.60.0>,<0.61.0>,<0.62.0>,
 <0.63.0>,<0.64.0>,<0.65.0>,<0.66.0>,<0.67.0>,<0.68.0>,
 <0.69.0>,<0.70.0>,<0.71.0>,<0.72.0>,<0.73.0>|...]
7> file_counter:increment().
10001

在进行每次调用之前，只需调用file_counter:increment()并使用其返回的值作为计数。

编辑：这只是我写的一个快速模块。您应该通过将文件名传递给start，start_link和init来配置文件名，如果您希望能够运行多个文件名，则不要使用名称注册该进程柜台的副本。这里的代码真的是一个让你入门的POC。

（在具有SSD磁盘的系统上，我能够每秒执行file_counter:increment()约5000次。）

如何计算Erlang中的函数调用次数？

1 个答案: