从REST响应代码获取变量值（SoapUI）

Question

这是我在运行REST请求时从TestCase1获得的响应（作为XML）：

<data contentType="text/plain" contentLength="88">
    <![CDATA[{"message":"success","data":{"export_id":"064c1948fe238d892fcda0f87e361400_1467676599"}}]]>
</data>

我想在测试用例2中使用export_id（dynamic）的值064c1948fe238d892fcda0f87e361400_1467676599。

我怎样才能做到这一点？我尝试使用属性转移，但我不知道如何配置。

Answer 1

您的回复很复杂，而不仅仅是使用属性转移提取所需值的xml。因为，它包含cdata，并且它内部再次包含json，您需要其中的值。

因此，为了获得该值，需要使用Groovy Script测试步骤而不是Property Transfer测试步骤。话虽如此，您删除了Property Transfer并将Groovy Script步骤放在同一个地方。

Groovy脚本的内容在这里：

/**
* This script reads a response xml string, extracts cdata at the specified xpath
* Then parse that string as Json and extract the required value
**/
import com.eviware.soapui.support.XmlHolder
import net.sf.json.groovy.JsonSlurper
//For testing using fixed value as you mentioned in the question
//However, you can use the dynamic response as well which is coming from the 
//previous step as well if you want
def soapResponse = '''
<data contentType="text/plain" contentLength="88"><![CDATA[{
           "message":"success",
           "data": 
           {
               "export_id":"064c1948fe238d892fcda0f87e361400_1467676599"
           }
      }]]>
</data>'''
def holder = new XmlHolder(soapResponse)
//Extract the data inside of CDATA section from the response
def data = holder.getNodeValue('//*:data')
//Parse the string with JsonSlurper
def json = new JsonSlurper().parseText(data)
log.info json
//Extract the export_id
def exportId =  json.data."export_id"
log.info "Export id : ${exportId}"
//Since you wanted to use the extracted value in another test case,
//Saving the value at test suite level custom property EXPORT_ID
//So that it can be used in any of the test case once the value is set
context.testCase.testSuite.setPropertyValue('EXPORT_ID', exportId)

如何在其他测试用例中使用export_id值？

• 如果您想在(REST / SOAP) Test Request测试步骤中使用该值，则可以使用属性扩展（即${#TestSuite#EXPORT_ID}）轻松使用该值。
• 如果您想在Groovy Script测试步骤中使用该值，则需要使用log.info context.expand('${#TestSuite#EXPORT_ID}')
获取值

如何在Groovy脚本中使用动态响应？

正如上面脚本中的内嵌注释所述，我已经展示了如何使用示例数据获取所需的值。

但是每次在脚本中替换变量soapRespone的值可能很困难，或者您也可能想要自动化这些内容。

在这种情况下，您只需要使用以下代码替换def soapResponse语句：

//Replace the previous step request test step name in place of "Test Request"
//Where you get the response which needs to be proceed in the groovy script
def soapResponse = context.expand('${Test Request#Response}')