Question

在bpel中，我们正在使用XSLT实现转换。以下是2个源XML文件和所需目标。我已应用身份匹配模板将source2复制到目标作为第一阶段。我无法通过任何匹配模板实现所需的输出。源1（查找）可以在XSLT中作为$lookup访问。

Source1（查询）：

<Lookup>
<values>
      <val>1</val>
      <val>2</val>
</values>
</Lookup>

Source2（小学）

<req>
<ref>
    <id>True</id>
    <val>1</val>
</ref>
<ref>
    <id>True</id>
    <val>2</val>
</ref>
<ref>
    <id>True</id>
    <val>1234</val>
</ref>
</req>

目标

<req>
<ref>
    <id>False</id>
    <val>1</val>
</ref>
<ref>
    <id>False</id>
    <val>2</val>
</ref>
<ref>
    <id>True</id>
    <val>1234</val>
</ref>
</req>

可以在XSLT中以$lookup的形式访问查找。我使用XSLT身份模板从源（主）复制到目标，但我无法通过模板匹配突破其余的匹配模式。

Answer 1

使用XSLT 2.0，您可以使用

<xsl:key name="ref" match="Lookup/values/val" use="."/>

然后

<xsl:template match="ref[key('ref', val, $lookup)]/id">
  <id>False</id>
</xsl:template>

与身份转换模板一起使用。

使用XSLT 1.0，您无法在匹配模式中使用该变量，而key函数没有该参数来更改上下文，因此不使用您可以使用的密钥

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:param name="lookup" select="document('source1.xml')"/>

    <xsl:template match="@* | node()" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="ref/id">
        <xsl:choose>
            <xsl:when test="../val = $lookup//val">
                <id>False</id>
            </xsl:when>
            <xsl:otherwise>
                <xsl:call-template name="identity"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

无法使用xslt模板匹配进行查找

1 个答案: