Question

我有一个测试文件，用于检查应用程序每个页面上是否存在所有关键元素（每页一个场景）。但是，该应用程序相当复杂，具有不同类型的用户（管理员，常规等），我希望能够与每种类型的用户一起浏览相同的pages.robot文件（并且可能有一些{{ 1}} if文件中的语句，适用于每种类型的用户），但我不确定应该怎么做。我猜测我应该使用pages.robot并使用Resource File，userType等设置全局admin变量并运行regular文件多次（每个用户类型一次），但我不确定如何设置pages.robot和Resource File变量。

关于userType应如何看待的任何想法，以及如何为每种类型的用户运行相同的文件？

Answer 1

您可以将测试用户配置/属性存储在资源文件（例如test_properties.txt）中，如下所示：

=== test_properties.txt ===

| *** Variables *** |
| ${tp_app_url}  | http://yourapp.com |
| ${tp_browser}  | firefox |
| ###### user roles to test with - admin, non-admin, regular |
| ${tp_user_type} | admin |
| ###### test users   |
| ${tp_admin_user} | admin@app.com |
| ${tp_admin_password} | admin@123 |
| ${tp_regular_user} | regular@app.com |
| ${tp_regular_password} | regular@123 |

此处，您要测试应用程序的用户角色/类型定义为：

| ###### user roles to test with - admin, regular |
| ${tp_user_type} | admin |

然后，您的测试套件文件可以导入资源文件，如下所示：

=== testsuite.txt ===

| *** settings *** |
| Library        | Selenium2Library |
| Resource       | test_properties.txt |

| *** test cases *** |
| Validate Page Controls |
|    | Open Browser To Login Page | ${tp_user_type} |
|    | Page Controls Should be Visible | ${tp_user_type} |

| *** keywords *** |
| Open Browser To Login Page |
|    | [Arguments] | ${user_type} |
|    | Open Browser | ${tp_app_url} | ${tp_browser} |
|    | Input Username | ${tp_${user_type}_user} |
|    | Input Password | ${tp_${user_type}_password} |
|    | Submit Credentials |
|    | Title Should Be | Welcome Page |

| Input Username |
|    | [Arguments] | ${username} |
|    | Input Text | username_field | ${username} |

| Input Password |
|    | [Arguments] | ${password} |
|    | Input Text | password_field | ${password} |

| Submit Credentials |
|    | Click Button | login_button |

| Page Controls Should be Visible |
|    | [Arguments] | ${user_type} |

与验证页面控件相关的代码可以驻留在关键字Page Controls Should be Visible中，该关键字将根据用户类型参数执行检查。

注意：此处通过将用户类型变量嵌入为${tp_${user_type}_user}来形成测试用户的userId和密码变量，在我们的案例中，该变量又被评估为${tp_admin_user}。

在执行期间，您可以在命令行上传递$ {tp_user_type}的值，并覆盖资源文件中设置的值。

pybot --variable tp_user_type:non-admin path/to/your/testfile

如果要使用多种用户类型运行相同的测试，可以创建一个批处理文件，如：

pybot --variable tp_user_type:non-admin path/to/your/testfile
pybot --variable tp_user_type:admin path/to/your/testfile
pybot --variable tp_user_type:regular path/to/your/testfile

我确定你的问题会有更好的解决方案。理想情况下，上面在测试套件文件中定义的关键字应该驻留在资源文件中。您还可以创建data-driven test以运行每个用户类型的模板关键字（验证页面控件）。

机器人框架 - 使用资源文件

1 个答案: