Question

如何在ftp中使用变量？这就是我所做的：档案a.bat：

set file=test ftp -s:b.txt IP

文件b.txt

user password get %file% quit

并且日志显示没有任何％file％。

Answer 1

ftp不了解Windows环境变量。您必须每次都生成脚本文件：

set file=test
set ftpscript=%TEMP%\ftp.txt
echo user> %ftpscript%
echo password>> %ftpscript%
echo get %file%>> %ftpscript%
echo quit>> %ftpscript%
ftp -s:%ftpscript% IP

这里我在temp目录中定义了一个临时脚本，因此它不会污染当前目录。

Answer 2

这是一个上传多个文件的例子：

@echo off
Title Multiple file Upload by Hackoo on adrive
Color 0A
::****** Settings for FTP ************
Set FTPSERVER=ftp.adrive.com
Set USER=Your Login
Set Password=Your Password
Set LocalFolder=C:\Hackoo
Set RemoteFolder=/backupFolder
::************************************
::--- FTP commands below here ---
> ft.do echo Open %FTPSERVER%
>> ft.do echo %USER%
>> ft.do echo %Password%
>> ft.do echo prompt n
>> ft.do echo bin
>> ft.do echo lcd %LocalFolder%
>> ft.do echo MkDir %RemoteFolder%
>> ft.do echo cd %RemoteFolder%
>> ft.do echo mput "*.*"
>> ft.do echo disconnect
>> ft.do echo bye
::************************************
ftp -s:ft.do
del ft.do
Pause

这是一个仅用于测试的示例，只能列出位于公共ftp服务器（如ftp.microsoft.com）上的文件夹中的文件，以便创建list.txt文件以进行下载之后，请尝试告诉我们结果。

@echo off
mode con cols=85 lines=22 & Color A
::***********************************
Set FTPSERVER=ftp.microsoft.com
Title Lister les fichiers et les dossiers sur un serveur FTP (%FTPSERVER%) by Hackoo
Set USER=anonymous
Set Password=anonymous@anonymous.com
Set DossierFTP=/bussys/winsock/winsock2/
Set DownloadFolder=winsock2
::*******************************************************
Goto Lister
:Lister
> ft.do echo Open %FTPSERVER%
>> ft.do echo %USER%
>> ft.do echo %Password%
>> ft.do echo prompt n
>> ft.do echo bin
>> ft.do echo cd %DossierFTP%
>> ft.do echo ls -h TLIST.txt
>> ft.do echo bye
ftp -s:ft.do
del ft.do
CLS
Color 9B
echo Download la liste
pause
Goto Download
::*********************************************************
:Download
> ft.do echo Open %FTPSERVER%
>> ft.do echo %USER%
>> ft.do echo %Password%
>> ft.do echo prompt n
>> ft.do echo bin
>> ft.do echo cd %DossierFTP%
for /F %%f in (TLIST.txt) do ( >> ft.do echo get %%f) 
>> ft.do echo bye
ftp -s:ft.do
del ft.do
CLS
Color 9A
pause
echo Deplacer la liste
Goto Deplacer
::*********************************************************
:Deplacer
Set Source=%~dp0
Set Destination=%Source%%DownloadFolder%
if not exist %DownloadFolder% MD %DownloadFolder%
for /F %%f in (TLIST.txt) do (move "%Source%%%f" "%Destination%")
pause

Answer 3

％-artifact在BAT文件中不起作用的原因是该令牌从未被看到和替换过。就像在UNIX shell脚本中一样，在收集和标记这些行时执行$ -substitutions。由于包含％file％的行被输入到FTP，因此它被FTP收集和解析，而不是“DOS”shell。

在UNIX中，您可以通过FTP管道指令来解决此问题。也就是说，虽然这个（其中$ 1是命令行提供的文件名参数）：

ftp << FTP_CMDS  
user joe  
pass joesPassword  
get $1  
quit  
FTP_CMDS

不起作用，这个：

(echo user joe;  
&nbsp;echo pass joesPassword;  
&nbsp;echo get $1;  
&nbsp;echo quit ) | ftp

工作。

在cmd中使用ftp连接中的变量

3 个答案: