Question

我正在寻找一种方法来重命名每个找到的.seg文件，以包含.seg文件上方两个目录的文件夹名称。

例如，我在

中找到了.seg文件

/data/test_all_runs/TestRun/Focus-HD753/QC/diffCoverage.seg

并想重命名

Focus-HD753.seg

我重命名该文件后，我想将其移至

/data/test_all_runs/TestRun

或$ARGV[0]。这是我目前的代码：

#!/usr/bin/perl
use warnings;
use strict;
use File::Find;
use File::Spec;

my $home = "/data";
my @location_parts = ($home, 'test_all_runs');
push @location_parts, $ARGV[0] if @ARGV;
my $location = File::Spec->catdir(@location_parts);

my @moves;
my @vcf_moves;
sub find_seg {
    my $F = $File::Find::name;
    if ($F =~ /\.seg$/ ) {
        my @path_parts = File::Spec->splitdir($F);
        my $name = $path_parts[-3];
        my $target = File::Spec->catdir($location, "$name.seg"); print $target;
        push @moves, [ $F, $target ];
    }
}   
find({ wanted => \&find_seg, no_chdir => 1 }, $home);

while (@moves) {
    my ($F, $target) = @{ shift @moves };
    warn "$F -> $target";
    rename $F, $target or warn "Can't move to $target";
}

sub find_vcf {
    my $V = $File::Find::name;
    if ($V =~ /(vcf$|oncomine\.tsv$)/ ) {
        my @path_parts = File::Spec->splitdir($V);
       print "The path_parts at 0 is #############".$path_parts[0]."\n";
       print "The path_parts at -1 is #############".$path_parts[-1]."\n";
       print "The path_parts at -2 is #############".$path_parts[-2]."\n";
       print "The path_parts at -3 is #############".$path_parts[-3]."\n";
       print "The path_parts at 1 is #############".$path_parts[1]."\n";
       my $target_vcf = File::Spec->catdir($location, $path_parts[-1]); print $target_vcf;
      push @vcf_moves, [ $V, $target_vcf ];
      print "$V\n";

    }
}

find({ wanted => \&find_vcf, no_chdir=>1}, $home);

while (@vcf_moves) {
    my ($V, $target_vcf) = @{ shift @vcf_moves };
    warn "$V -> $target_vcf";
    rename $V, $target_vcf or warn "Can't move to $target_vcf";
}

Answer 1

使用rename将文件移动到名称目的地和名称。 File::Spec使代码OS独立。您还可以检查Path::Tiny是否有类似的任务。

移动被保存在一个数组中并在以后执行，否则File :: Find可能会在遍历目录时多次移动同一个文件。

#!/usr/bin/perl
use warnings;
use strict;
use File::Find;
use File::Spec;

my $home = "/data";
my @location_parts = ($home, 'test_all_runs', 'TestRun');
push @location_parts, $ARGV[0] if @ARGV;
my $location = File::Spec->catdir(@location_parts);

my @moves;
sub find_seg {
    my $F = $File::Find::name;

    if ($F =~ /\.seg$/ ) {
        my @path_parts = File::Spec->splitdir($F);
        my $name = $path_parts[-3];
        my $target = File::Spec->catdir($location, "$name.seg");
        push @moves, [ $F, $target ];
    }
}

find({ wanted => \&find_seg, no_chdir => 1 }, $home);
while (@moves) {
    my ($F, $target) = @{ shift @moves };
    warn "$F -> $target";
    rename $F, $target or warn "Can't move to $target";
}

Answer 2

对于名称文件名修改，您可以使用This模块，它是核心的一部分。

#!/usr/bin/env perl
use strict;
use warnings;
use feature qw{say};
use File::Basename;

my $filePath = "/data/test_all_runs/TestRun/Focus-HD753/QC/diffCoverage.seg";
my ($filename, $directories, $extension) = fileparse($filePath, '.seg');

my $target = (split m{/}, $directories)[-2];
say "Target: $target";

my $newFilePath = "$directories$target$extension";
say $newFilePath;

结果：

Target: Focus-HD753
/data/test_all_runs/TestRun/Focus-HD753/QC/Focus-HD753.seg

然后您可以使用$ARGV[0]将其移动到您想要的位置（可能使用File::Basename？）

批量重命名并在Perl中移动文件

2 个答案: