Question

我尝试过SWFLoader，但问题是加载的内容是MovieClip，我不知道如何与它进行交互，而且MovieClip＃numChildren为零。

顺便说一句，我无法将闪光灯传递给瑞士法郎。

Answer 1

首先，你应该知道你的问题没有确切的答案，因为它取决于你加载的SWF（你知道与否，它的显示列表，......）但我会举一个简单的例子来解释事情，你必须适应你的情况。

对于这个例子，让我们说我们有一个非常简单的SWF（加载的SWF），它包含一个TextField（称为txt_url）和一个按钮（一个名为btn_go的MovieClip ）。

btn_go按钮将打开在txt_url TextField中输入的网址。

对于我们的第二个SWF（加载器），我们将使用Loader对象加载我们的第一个（在这种情况下将是Loader.content），然后我们将设置URL（ txt_url文字）并触发btn_go按钮上的点击事件。

以下是我们loader.swf的代码示例：

var loader:Loader = new Loader();
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, on_SWFLoad);
    loader.load(new URLRequest('loaded.swf'));
    addChild(loader);

function on_SWFLoad(e:Event): void
{   
    // get our loaded SWF
    var loaded_swf:DisplayObjectContainer = DisplayObjectContainer(loader.content);

    // because we know our target objects, we can use "getChildByName()"
    // set the URL
    TextField(loaded_swf.getChildByName('txt_url')).text = 'http://www.example.com';

    // open the URL in the browser by triggering the click event on the "btn_go" button
    MovieClip(loaded_swf.getChildByName('btn_go')).dispatchEvent(new MouseEvent(MouseEvent.CLICK));     
}

此示例将在加载SWF后直接在浏览器中设置和打开URL，当然我们可以在点击按钮或其他内容后执行该操作，但它只是一个简单的示例，向您展示如何做......

现在，问题是当我们对加载的SWF及其子项（名称，深度......）一无所知时，在这种情况下我们应该做更多努力来做我们想要的事情：我们应该遍历加载的SWF的整个显示列表以识别目标对象。

回到我们的例子，让我们说我们只知道舞台上有一个TextField和一个按钮，所以我们的代码就像这样：

function on_SWFLoad(e:Event): void
{
    var loaded_swf:DisplayObjectContainer = DisplayObjectContainer(loader.content);
    var num_children:int = loaded_swf.numChildren;

    for(var i:int = 0; i < num_children; i++)
    {
        var child:DisplayObject = loaded_swf.getChildAt(i); 

        if(child is TextField)
        {
            trace(child.name);          // gives : txt_url
            TextField(child).text = 'http://www.example.com';
        }
        else 
        {
            if(child.hasEventListener(MouseEvent.CLICK))
            {
                trace(child.name);      // gives : btn_go
                child.dispatchEvent(new MouseEvent(MouseEvent.CLICK));
            }
        }
    }
}

同样，这是一个非常简单的例子，只是为了展示我们如何继续......

...

然后关于在SWF之间传递值（参数），看看my answer of this question那里有一个小例子。

有关Display programming（显示列表，显示对象，显示对象容器......）的更多信息，请查看here。

希望可以提供帮助。

如何加载swf并与之交互？

1 个答案: