Question

我知道使用列的readonly属性，我可以避免编辑其字段值。但这并不能阻止现场编辑器展示自己。我需要一种方法来使列不仅受到保护而且“不可触及”。有办法吗？

Answer 1

如果我理解你想要什么，你可以通过创建一个自定义的TDBGrid后代并覆盖它来做到这一点。其CanEditShow方法，因为这决定了是否可以创建网格InplaceEditor：

type
  TMyDBGrid = class(TDBGrid)
  private
    FROColumn: Integer;
  protected
    function CanEditShow : Boolean; override;
  public
    property ROColumn : Integer read FROColumn write FROColumn;
  end;

function TMyDBGrid.CanEditShow: Boolean;
begin
  Result := Inherited CanEditShow;
  Result := Result and (Col <> ROColumn);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  MyDBGrid := TMyDBGrid.Create(Self);
  MyDBGrid.ROColumn := 1;
  MyDBGrid.DataSource := DataSource1;
  MyDBGrid.Parent := Self;
[...]

这个极简主义的例子只是将一个网格列按编号定义为一个不允许InplaceEditor的地方;显然你可以使用任何机制您想识别CanEditShow返回False的列。

请注意，如果您关闭Indicator列（即将Options.dgIndicator设置为False），上面的代码并不能说明网格的列编号会发生变化;

显然，您可以通过使用可分配事件来自定义哪些列允许使用InplaceEditor，从而获得更多灵活性，如

type

  TAllowGridEditEvent = procedure(Sender : TObject; var AllowEdit : Boolean) of object;

  TMyDBGrid = class(TDBGrid)
  private
    FOnAllowEdit: TAllowGridEditEvent;
  protected
    function CanEditShow : Boolean; override;
    procedure DoAllowEdit(var AllowEdit : Boolean);
  public
    property OnAllowEdit : TAllowGridEditEvent read FOnAllowEdit write FOnAllowEdit;
  end;

function TMyDBGrid.CanEditShow: Boolean;
begin
  Result := Inherited CanEditShow;
  if Result then
    DoAllowEdit(Result);
end;

procedure TMyDBGrid.DoAllowEdit(var AllowEdit: Boolean);
begin
  if Assigned(FOnAllowEdit) then
    FOnAllowEdit(Self, AllowEdit);
end;

procedure TForm1.AllowEdit(Sender: TObject; var AllowEdit: Boolean);
var
  Grid : TMyDBGrid;
begin
  Grid := Sender as TMyDBGrid;
  AllowEdit := Grid.Col <> 1;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  MyDBGrid := TMyDBGrid.Create(Self);
  MyDBGrid.ROColumn := 1;
  MyDBGrid.DataSource := DataSource1;
  MyDBGrid.Parent := Self;
  MyDBGrid.OnAllowEdit := AllowEdit;
  [...]

如果您不想在代码中创建网格，可以将其放在自定义包中并进行安装在IDE 或中，如果您的Delphi版本足够新，请执行 CanEditShow中的class helper。

Delphi：避免在TDBgrid中编辑列

1 个答案: