Question

任何人都有一个示例代码或说明来使这项工作？我从来没有能够完成使用箭头键并输入选择的突出显示的菜单。提前谢谢！

更新！我期望这可以通过为每个选项绘制框，并在选择选项时为文本着色时重绘颜色框，我只是不确定如何设计循环来实现这一点。我对INKEY $和SELECT CASE函数很满意，但我不知道如何将它们考虑在内。

Answer 1

突出显示的菜单将绘制菜单并等待循环按键或使用SLEEP。一种常见的替代方法是简单地更改前几个字母之一的文本颜色，通知用户按相应的键以选择相应的菜单选项。例如，字母Q在＆＃34; Quit＆＃34;和N在＆＃34;新游戏＆＃34;将与该行中其余文本的颜色不同。

但是，您要求使用箭头键，所以很明显您不想这样做。如何突出显示当前菜单项取决于使用的屏幕模式。屏幕模式11,12和13不允许您指定背景颜色，我无法让DOSBox渲染模式7,8和9的背景。作为此问题的解决方法，你可以简单地在当前选择旁边画一个框并擦除框（画一个黑色的或任何你的屏幕的背景颜色）。或者您可以使用星号来避免图形/文本大小问题并简化代码。这里是一个带箭头键，WASD键和Vim风格键（H = Left，J = Down，K = Up，L = Right）的盒子样式的例子，假设US-QWERTY键盘是用过的。如果您只想要箭头键，那么您只需要将第一个（外部）SELECT CASE...END SELECT块更改为IF LEFT$(k$, 1) = CHR$(0) THEN...END IF，同时保留使用扩展键的内部SELECT CASE...END SELECT块

'size% is used in the selIncDec subroutine.
DIM text$(0 TO 3)
DIM SHARED size%
size% = UBOUND(text$) - LBOUND(text$) + 1

selected% = 0

text$(0) = "Example 1"
text$(1) = "Example 2"
text$(2) = "Example 3"
text$(3) = "Example 4"

SCREEN 12

' Width and height of a text cell in pixels.
' I use 8x8 text cells for max screen compatibility, despite 8x16 looking better.
xpxText% = 8
ypxText% = 8

' See the documentation for SCREEN to determine which screen sizes are
' available with the screen mode you want to use.
' 80x60 for mode 12 results in 8x8 text cells. 80x30 results in 8x16 text cells.
WIDTH 80, 60

DO
    LOCATE 1, 1
    FOR i% = LBOUND(text$) TO UBOUND(text$)
        PRINT TAB(3); text$(i%)
        '    selected% = i%
        ' is an equality comparison, resulting in -1 for true and 0 for false.
        ' If false, -(0) * 2 = 0; if true, -(-1) * 2 = 2.
        LINE (0, i% * ypxText%)-STEP(xpxText% - 1, xpxText% - 1), -(selected% = i%) * 2, BF
    NEXT i%

    SLEEP
    k$ = INKEY$
    SELECT CASE UCASE$(LEFT$(k$, 1))
      ' Left -- does nothing
      CASE "H", "A"

      ' Right -- does nothing
      CASE "L", "D"

      ' Up
      CASE "K", "W"
        CALL selIncDec(selected%, -1)

      ' Down
      CASE "J", "S"
        CALL selIncDec(selected%, 1)

      ' Enter key
      CASE CHR$(13)
        EXIT DO

      ' Extended key, such as arrows.
      CASE CHR$(0)
        SELECT CASE RIGHT$(k$, 1)
          ' Left
          CASE "K"

          ' Right
          CASE "M"

          ' Up
          CASE "H"
            CALL selIncDec(selected%, -1)

          ' Down
          CASE "P"
            CALL selIncDec(selected%, 1)
        END SELECT
    END SELECT
LOOP

PRINT USING "You selected option #"; selected% + 1

END

SUB selIncDec (selected%, amtInc%)
    selected% = selected% + amtInc%
    IF selected% >= size% THEN
        selected% = selected% - size%
    ELSEIF selected% < 0 THEN
        selected% = selected% + size%
    END IF
END SUB

如果您使用支持背景颜色或以某种形式突出显示的屏幕模式（例如屏幕0），您可能只需轻轻一点＆＃34;突出显示＆＃34;整个行在文本模式下的背景。您无需指定屏幕的宽度即可拥有＆＃34;反向视频＆＃34;效果作为突出显示，但当您突出显示整行而不仅仅是文本时，它看起来更好。打印完该菜单项后，只需将颜色更改回默认值并继续照常打印。下面显示了对上述代码（屏幕模式，屏幕宽度设置和菜单显示代码）的一些更改，但它保持不变：

SCREEN 0
'8x8 text cells in SCREEN 0 for VGA adapters.
WIDTH 80, 43

...

    FOR i% = LBOUND(text$) TO UBOUND(text$)
        ' "Reverse video" highlighting.
        IF selected% = i% THEN COLOR 0, 7 ELSE COLOR 7, 0
        PRINT TAB(3); text$(i%); SPACE$(78 - LEN(text$(i%)))
    NEXT i%

    ' The screen will turn "white" when the last menu item is selected.
    ' This fixes the issue.
    COLOR 7, 0

    SLEEP
...

请注意，我假设一个带有彩色显示器的VGA适配器用于上述所有代码，这些代码早已被各种其他显示适配器标准所取代，即使在智能手表这样小的设备上也是如此。

您应该能够调整代码以满足您的需求。我设计它，你可以根据需要简单地添加菜单项。此外，显示代码本身完全包含在FOR...NEXT循环中，其功能紧随其后，因此您需要更改的是FOR...NEXT循环内的内容，以更改内容的显示方式

Qbasic突出显示菜单，认真

1 个答案: