CMake为Win32和x64生成Visual Studio 2008解决方案

Question

我在Windows XP下使用CMake 2.8并希望生成一个Visual Studio 2008解决方案文件，其中包含Win32和x64的发布和调试配置。

可以通过在CMakeLists.txt文件中设置CMake配置变量来完成吗？

Answer 1

CMakeLists不是您为项目指定生成器（makefile，XCode，Visual Studio）的地方。当用户在源上运行CMake时指定生成器。

Answer 2

您应该在具有CMake.exe的控制台下生成解决方案文件。

CMake -G“Visual Studio 9 2008”（包含CMakeLists.txt文件的目录）//这适用于X86。

CMake -G“Visual Studio 9 2008 Win64”（包含CMakeLists.txt文件的目录）//这适用于X64。

Answer 3

您绝对应该使用批处理脚本来自动执行这些过程。我和你分享了我自己的构建器脚本的简化版本。我自己的环境要复杂得多，因此我编写了这个脚本供您轻松使用。

它的用法非常基本。

builder . -64bit -Debug

表示源代码在当前目录中，编译配置为64位Debug版本。

您只需在脚本中更改全局配置变量即可 visual studio目录和cmake目录。

SET VISUAL_STUDIO_9_HOME =

SET CMAKE_HOME =

@echo off

rem ===== Usage
rem builder c:\workspace\project1 -32bit -Release
rem builder . -64bit -Debug

rem Global configuration variables. Should be update based on your system
SET VISUAL_STUDIO_9_HOME=c:\Program Files\Microsoft Visual Studio 9.0
SET CMAKE_HOME=c:\Documents and Settings\stumk\My Documents\toolkit\cmake

rem First parameter is project folder path
SET PROJECT_DIR=%1

rem Add executables into path
rem Only add them once
if NOT DEFINED SETENV  SET SETENV=0
if %SETENV% EQU 0 SET PATH=%CMAKE_HOME%\bin;%VISUAL_STUDIO_9_HOME%\Common7\Tools;%PATH%
SET SETENV=1

rem Go to project director
cd %PROJECT_DIR%

rem Create build folder, don't mess the source code with visual studio project files
md build

rem Go to build folder
cd build\
   rem Set visual studio environment variables
   call vsvars32.bat 

   rem Second parameter defines 32 bit or 64 bit compilation
   if "%2"=="-32bit" (
       cmake.exe .. -G "Visual Studio 9 2008"
   )
   if "%2"=="-64bit" (
       cmake.exe .. -G "Visual Studio 9 2008 Win64"
   )

   rem Third parameter defines debug or release compilation
   if "%3"=="-Debug" (
           cmake.exe --build . --target ALL_BUILD --config Debug
   )
   if "%3"=="-Release" (
           cmake.exe --build . --target ALL_BUILD --config Release
   )

   rem Go to source code directory and finalize script
   cd ..

@echo on