Question

我是spacemacs粉丝。我想使用Facebook Flow，但我不知道如何将它与spacemacs集成。我正在使用nuclide的流程，但我需要重新学习所有内容才能提高效率。 flow存储库上有this script与emacs一起使用它。我需要一个如何在spacemacs中使用它的指南。

感谢。

Answer 1

我在这里使用了Bodil的flow flycheck配置：https://github.com/bodil/emacs.d/blob/d28264cf072bb8a62459a48813d0cb30804b4f5b/bodil/bodil-js.el#L121-L154

通过将以下内容添加到我的react-mode（https://github.com/saltycrane/.spacemacs.d/blob/9d985ace9251529c2b8d7857e2ec9835b103084c/init.el#L383-L414），我使用了spacemacs的dotspacemacs/user-config和默认的eslint flychecker：

;; Flow (JS) flycheck config (http://flowtype.org)
;; from https://github.com/bodil/emacs.d/blob/master/bodil/bodil-js.el
(require 'f)
(require 'json)
(require 'flycheck)

(defun flycheck-parse-flow (output checker buffer)
  (let ((json-array-type 'list))
    (let ((o (json-read-from-string output)))
      (mapcar #'(lambda (errp)
                  (let ((err (cadr (assoc 'message errp))))
                    (flycheck-error-new
                     :line (cdr (assoc 'line err))
                     :column (cdr (assoc 'start err))
                     :level 'error
                     :message (cdr (assoc 'descr err))
                     :filename (f-relative
                                (cdr (assoc 'path err))
                                (f-dirname (file-truename
                                            (buffer-file-name))))
                     :buffer buffer
                     :checker checker)))
              (cdr (assoc 'errors o))))))

(flycheck-define-checker javascript-flow
  "Javascript type checking using Flow."
  :command ("flow" "--json" source-original)
  :error-parser flycheck-parse-flow
  :modes react-mode
  :next-checkers ((error . javascript-eslint))
  )
(add-to-list 'flycheck-checkers 'javascript-flow)

还要确保安装了Flow命令行工具。像这样安装：

npm install -g flow-bin

我认为Bodil打算简短地发布消息，但我想让flycheck显示更详细的消息。如果有人知道如何做到这一点，我会很感激。

编辑2016-08-12：我发布的原始版本在初始加载时出现Symbol's function definition is void: flycheck-define-checker错误。我更新了上面的代码，添加require 'flycheck以消除该错误。

Answer 2

saltycrane的答案对我来说很好。谢谢！他指出，该解决方案提供了非常短的错误消息。我已将错误消息改进为更详细，看起来更像是流cli输出的输出。

对于想要使用此脚本的新用户，请注意确保您对其进行编辑，以便在底部的flycheck-define-checker中使用正确的模式。我在js2-mode中使用它，而saltycrane使用react-mode。编辑它以使用您正在使用的任何内容。

(require 'f)
(require 'json)
(require 'flycheck)
(defun flycheck-parse-flow (output checker buffer)
  (let ((json-array-type 'list))
    (let ((o (json-read-from-string output)))
      (mapcar #'(lambda (errp)
                  (let ((err (cadr (assoc 'message errp)))
                        (err2 (cadr (cdr (assoc 'message errp)))))
                    (flycheck-error-new
                     :line (cdr (assoc 'line err))
                     :column (cdr (assoc 'start err))
                     :level 'error
                     :message (concat (cdr (assoc 'descr err)) ". " (cdr (assoc 'descr err2)))
                     :filename (f-relative
                                (cdr (assoc 'path err))
                                (f-dirname (file-truename
                                            (buffer-file-name))))
                     :buffer buffer
                     :checker checker)))
              (cdr (assoc 'errors o))))))

(flycheck-define-checker javascript-flow
  "Static type checking using Flow."
  :command ("flow" "--json" source-original)
  :error-parser flycheck-parse-flow
  :modes js2-mode)
(add-to-list 'flycheck-checkers 'javascript-flow)

如何将flowtype与spacemacs集成

2 个答案: