Question

我在Delphi中创建了一个程序来创建服务器并监听客户端的响应。客户端连接到服务器，发送一些数据，并立即断开连接。问题是，有时收到我的程序的数据停止响应。大多数时候，当我关闭程序时，我看到EOSError 1400 [无效的窗口句柄。]（我知道这个错误是因为socks线程）。我在关闭窗口之前将TCPServer的Active属性设置为false。我测试了TTCPServer和TIdTCPServer，但问题没有解决。

这是我的TTCPServer代码：

procedure TMonitorFrm.TcpSerAccept(Sender: TObject;
  ClientSocket: TCustomIpClient);
var
  b: array [0..300] of Byte;
  z, k: Byte;
  s: String;
begin
repeat
  z := ClientSocket.ReceiveBuf(b, SizeOf(b), 0);
  s := '';
  if (z > 6) then
    begin
    for k := 0 to z - 1 do
      begin
      s := s + IntToHex(b[k], 2);
      if (k in [2, 5, 6]) then s := s + ' ';
      end;
    FullLst.Items.Add(s);
    FullMessageEdt.Text := s;
    if (Length(s) > 17) then Delete(s, 1, 17) else s := '';
    k := MessagesGrd.RowCount;
    MessagesGrd.RowCount := k + 1;
    MessagesGrd.Cells[0, k] := Format('%d.%d.%d', [b[3], b[4], b[5]]);
    MessagesGrd.Cells[1, k] := Format('%d.%d.%d:%d', [b[0], b[1], b[2], b[6]]);
    MessagesGrd.Cells[2, k] := s;
    MessagesGrd.Cells[3, k] := TimeToStr(Now);
    MessagesGrd.Row := k;
    end;
until (z = 0);
Application.ProcessMessages;
end;

这是我的TIdTCPServer代码：

procedure TMonitorFrm.IdTCPSerExecute(AContext: TIdContext);
var
  r: TIdBytes;
  k: Byte;
  s: String;
begin
AContext.Connection.IOHandler.ReadTimeout := TCPTimeOut;
AContext.Connection.IOHandler.ReadBytes(r, -1, False);
if (Length(r) > 6) then
  begin
  for k := 0 to High(r) do
    begin
    s := s + IntToHex(r[k], 2);
    if (k in [2, 5, 6]) then s := s + ' ';
    end;
  FullLst.Items.Add(s);
  FullMessageEdt.Text := s;
  if (Length(s) > 17) then Delete(s, 1, 17) else s := '';
  k := MessagesGrd.RowCount;
  MessagesGrd.RowCount := k + 1;
  MessagesGrd.Cells[0, k] := Format('%d.%d.%d', [b[3], b[4], b[5]]);
  MessagesGrd.Cells[1, k] := Format('%d.%d.%d:%d', [b[0], b[1], b[2], b[6]]);
  MessagesGrd.Cells[2, k] := s;
  MessagesGrd.Cells[3, k] := TimeToStr(Now);
  MessagesGrd.Row := k;
  end;
Finalize(r);
Application.ProcessMessages;
end;

Answer 1

这两个代码示例的问题在于它们正在从主UI线程的上下文之外操作UI控件。这两个代码都在工作线程中运行其客户端I / O，因此它们必须与主UI线程同步。一种方法是使用TThread.Synchronize()方法，例如：

procedure TMonitorFrm.TcpSerAccept(Sender: TObject;
  ClientSocket: TCustomIpClient);
var
  b: array [0..300] of Byte;
  z, k: Byte;
  s: String;
begin
  repeat
    z := ClientSocket.ReceiveBuf(b, SizeOf(b), 0);
    s := '';
    if (z > 6) then
    begin
      for k := 0 to z - 1 do
      begin
        s := s + IntToHex(b[k], 2);
        if (k in [2, 5, 6]) then s := s + ' ';
      end;
      TThread.Synchronize(nil,
        procedure
        begin
          FullLst.Items.Add(s);
          FullMessageEdt.Text := s;
          k := MessagesGrd.RowCount;
          MessagesGrd.RowCount := k + 1;
          MessagesGrd.Cells[0, k] := Format('%d.%d.%d', [b[3], b[4], b[5]]);
          MessagesGrd.Cells[1, k] := Format('%d.%d.%d:%d', [b[0], b[1], b[2], b[6]]);
          MessagesGrd.Cells[2, k] := Copy(s, 18, MaxInt);
          MessagesGrd.Cells[3, k] := TimeToStr(Now);
          MessagesGrd.Row := k;
        end
      );
    end;
  until (z = 0);
end;

procedure TMonitorFrm.IdTCPSerConnect(AContext: TIdContext);
begin
  AContext.Connection.IOHandler.ReadTimeout := TCPTimeOut;
end;

procedure TMonitorFrm.IdTCPSerExecute(AContext: TIdContext);
var
  r: TIdBytes;
  k: Byte;
  s: String;
begin
  AContext.Connection.IOHandler.ReadBytes(r, -1, False);
  if (Length(r) > 6) then
  begin
    for k := 0 to High(r) do
    begin
      s := s + IntToHex(r[k], 2);
      if (k in [2, 5, 6]) then s := s + ' ';
    end;
    TThread.Synchronize(nil,
      procedure
      begin
        FullLst.Items.Add(s);
        FullMessageEdt.Text := s;
        k := MessagesGrd.RowCount;
        MessagesGrd.RowCount := k + 1;
        MessagesGrd.Cells[0, k] := Format('%d.%d.%d', [b[3], b[4], b[5]]);
        MessagesGrd.Cells[1, k] := Format('%d.%d.%d:%d', [b[0], b[1], b[2], b[6]]);
        MessagesGrd.Cells[2, k] := Copy(s, 18, MaxInt);
        MessagesGrd.Cells[3, k] := TimeToStr(Now);
        MessagesGrd.Row := k;
      end
    );
  end;
end;

然而，说到这一点，小心不要在与主UI线程同步时从主UI线程中停用任一服务器。这是一个有保障的僵局。你必须要么：

确保在停用服务器之前没有正在进行同步请求。
使用异步UI更新而不是同步更新。您可以使用TThread.Queue()，TIdNotify等。或者将数据存储在线程安全变量中，然后使用UI计时器定期更新UI。这样，当主UI线程停用服务器时，I / O线程不会被阻止。
使用另一个线程停用服务器，以便主用户界面线程可以在停用繁忙时继续处理同步请求。

TCPServer和Error1400

1 个答案: