列的类型与UNPIVOT列表中指定的其他列的类型冲突

Question

我在不同的数据库中有两个表，我正在尝试将它们合并在一起以创建资产列表及其读数。我提出了以下问题：

use [db1]
DECLARE @colsUnpivot AS NVARCHAR(MAX),
   @query  AS NVARCHAR(MAX)
select @colsUnpivot 
  = stuff((select ','+quotename(C.name)
           FROM sys.columns c
           where c.object_id = OBJECT_ID('db1.dbo.RUNTIME') and c.name != 'timestamp'
           for xml path('')), 1, 1, '')


use [db2]
set @query = '
SELECT
  a.[ID],
  a.[ASSETCLASS],
  a.[ASSETID],
  a.[READINGNAME],
  CONVERT(nvarchar(max), a.[SCADA_TAG]) as [SCADA_TAG],
  b.timestamp AS [READINGDATE],
  b.scada_value AS [READING]
/*,[PROCESSED]*/ FROM [scada].[PREPROCESSING] a
LEFT JOIN (SELECT
  [timestamp],
  CONVERT(nvarchar(max), [SCADA_TAG]) as [SCADA_TAG],
  [SCADA_VALUE]
FROM [db1].[dbo].[RUNTIME] UNPIVOT (SCADA_VALUE FOR SCADA_TAG IN ('+ @colsUnpivot +')) u) b
  ON a.scada_tag = b.scada_tag'

  exec sp_executesql @query;

但是，我在运行查询时收到以下错误消息：

当我查看上述列的数据类型时，db1数据库有两种不同的数据类型，用于我试图选择的列-love和int。我试图将这些列名称从db1放入db2的列的数据类型为nvarchar（100）。我已经尝试过铸造和转换SCADA_TAG而没有成功。我刚刚从另一个开发者那里继承了这个SQL集成，而且我对使用pivot和unpivot功能感到厌烦。任何帮助或建议将不胜感激。

Answer 1

我知道这可能会迟到。但是你可以先尝试的几乎就像在两个表上进行模式比较一样。检查哪些列或数据类型不相同。见下面的脚本。

SELECT c.name AS ColumnName,
    t.name AS DataType,
    c.max_length
FROM [DB1].sys.columns  c
INNER JOIN [DB1].sys.types  t 
    ON c.user_type_id=t.user_type_id
WHERE OBJECT_NAME(object_id ) = 'TableName'


 EXCEPT

SELECT c.name AS ColumnName,
    t.name AS DataType,
    c.max_length
FROM [DB2].sys.columns  c
INNER JOIN [DB2].sys.types t 
    ON c.user_type_id=t.user_type_id
WHERE OBJECT_NAME(OBJECT_ID) = 'TableName'

Answer 2

我最终做了什么，这可能不是最有效的处理方法，是从源数据库获取列并将其转换并选择到NVARCHAR（100）列。

USE [db1]
DECLARE @tagNames AS nvarchar(max),
        @query AS nvarchar(max)
SELECT
  @tagNames
  = STUFF((SELECT
    ', CAST(' + QUOTENAME(C.name) + ' as nvarchar(100)) as ' + QUOTENAME(c.name)
  FROM sys.columns c
  WHERE c.object_id = OBJECT_ID('db1.dbo.RUNTIME')
  AND c.name != 'timestamp'
  FOR xml PATH (''))
  , 1, 1, '')

USE [db2]
SET @query = 'select [timestamp], ' + @tagNames + ' into test_runtime from
  [db1].dbo.RUNTIME'
EXEC sp_executesql @query

这为我提供了一个与原始表格具有相同结构和值的表格，但除了[timestamp]列之外，所有列都已转换为NVARCHAR。然后，我可以运行以下SQL来返回资产和读数的不重要和合并的结果集：

DECLARE @colsUnpivot AS nvarchar(max),
        @query AS nvarchar(max)
SELECT
  @colsUnpivot
  = STUFF((SELECT
    ',' + QUOTENAME(C.name)
  FROM sys.columns c
  WHERE c.object_id = OBJECT_ID('dbo.test_RUNTIME')
  AND c.name != 'timestamp'
  FOR xml PATH (''))
  , 1, 1, '')

SET @query = '
SELECT
  a.[ID],
  a.[ASSETCLASS],
  a.[ASSETID],
  a.[READINGNAME],
  a.[SCADA_TAG],
  b.timestamp AS [READINGDATE],
  b.scada_value AS [READING]
FROM [scada].[PREPROCESSING] a
LEFT JOIN (SELECT
  [timestamp],
  [scada_tag],
  [SCADA_VALUE]
FROM [dbo].[test_RUNTIME] UNPIVOT (SCADA_VALUE FOR SCADA_TAG IN (' + @colsUnpivot + ')) u) b
  ON a.scada_tag = b.scada_tag'

EXEC sp_executesql @query;
GO

如果有一种更有效的方法，我全都是耳朵。