Question

我有一个Elixir程序，我想通过IO.gets多次测试哪些来自用户的输入。我如何在测试中伪造这个输入？

注意：我想为每个IO.gets

返回不同的值

Answer 1

这样做的首选方法是将代码分为纯（无副作用）和不纯（io）。因此，如果您的代码如下所示：

IO.gets
...
...
...
IO.gets
...
...

尝试将IO.gets之间的部分提取到您可以独立于IO.gets进行测试的函数中：

def fun_to_test do
  input1 = IO.gets
  fun1(input1)
  input2 = IO.gets
  fun2(input2)
end

然后您可以单独测试这些功能。这并不总是最好的事情，特别是如果不纯的部分深入if，case或cond语句。

另一种方法是将IO作为显式依赖项传递：

def fun_to_test(io \\ IO) do
  io.gets
  ...
  ...
  ...
  io.gets
  ...
  ...
end

通过这种方式，您可以在不进行任何修改的情况下从生产代码中使用它，但在测试中，您可以将其传递给不同的模块fun_to_test(FakeIO)。如果提示不同，您可以在gets参数上进行模式匹配。

defmodule FakeIO do
  def gets("prompt1"), do: "value1"
  def gets("prompt2"), do: "value2"
end

如果它们始终相同，则需要保持调用gets的次数状态：

defmodule FakeIO do
  def start_link do
    Agent.start_link(fn -> 1 end, name: __MODULE__)
  end

  def gets(_prompt) do
    times_called = Agent.get_and_update(__MODULE__, fn state ->
      {state, state + 1}
    end)
    case times_called do
      1 -> "value1"
      2 -> "value2"
    end
  end
end

这最后一个实现是一个完全有效的模拟及其内部状态。在测试中使用它之前，您需要调用FakeIO.start_link。如果这是你需要在许多地方做的事情，你可以考虑一些模拟库，但正如你所看到的 - 这不是太复杂。为了使FakeIO更好，您可以打印提示。我在这里略过了这个细节。

Answer 2

在接受的答案中找到FakeIO解决方案非常有帮助。希望添加另一个明确的示例，并在需要时指出从FakeIO到真实IO的委派

在这里，我有一个简单的要求，即编写一个带有一点IO的应用程序，从STDIN读取一个名称并回复STDOUT。

示例输出

你叫什么名字？ Elixir

你好，Elixir，很高兴见到你！

下面是“app”，一个名为Ex1的模块：

defmodule Ex1 do

  def sayHello(io \\ IO) do
    "What is your name? "
    |> input(io)
    |> reply
    |> output(io)
  end

  def input(message, io \\ IO) do
    io.gets(message) |> String.trim
  end

  def reply(name) do
   "Hello, #{name}, nice to meet you!"
  end

  def output(message, io \\ IO) do
    io.puts(message)
  end

end

以及相关的测试：

defmodule FakeIO do
  defdelegate puts(message), to: IO
  def gets("What is your name? "), do: "Elixir "
  def gets(value), do: raise ArgumentError, message: "invalid argument #{value}"
end

defmodule Ex1Test do
  use ExUnit.Case
  import ExUnit.CaptureIO
  doctest Ex1

  @tag runnable: true
  test "input" do
    assert Ex1.input("What is your name? ", FakeIO) == "Elixir"
  end

  @tag runnable: true
  test "reply" do
    assert Ex1.reply("Elixir") == "Hello, Elixir, nice to meet you!"
  end

  @tag runnable: true
  test "output" do
    assert capture_io(fn ->
      Ex1.output("Hello, Elixir, nice to meet you!", FakeIO)
    end) == "Hello, Elixir, nice to meet you!\n"
  end

  @tag runnable: true
  test "sayHello" do
    assert capture_io(fn ->
      Ex1.sayHello(FakeIO)
    end) == "Hello, Elixir, nice to meet you!\n"
  end

end

有趣的是将FakeIO与参数模式匹配结合使用，并defdelegate委托给真正的IO.puts调用。 gets上有一个“catchall”模式，如果将预期的获取参数传递给FakeIO，则会引发ArgumentError。

 defmodule FakeIO do
   defdelegate puts(message), to: IO
   def gets("What is your name? "), do: "Elixir "
   def gets(value), do: raise ArgumentError, message: "invalid argument #{value}"
 end

无论如何，希望这可以提供有关FakeIO使用的一些见解。

使用ExUnit进行测试时如何伪造IO输入？

2 个答案: