Question

这是我的代码：

%lex
%options flex

%{
// Used to store the parsed data
if (!('regions' in yy)) {
    yy.regions = {
        settings: {},
        tables: [],
        relationships: []
    };
}
%}

text                [a-zA-Z][a-zA-Z0-9]*

%%

\n\s*               return 'NEWLINE';
[^\S\n]+            ; // ignore whitespace other than newlines
"."                 return '.';
","                 return ',';
"-"                 return '-';
"="                 return '=';
"=>"                return '=>';
"<="                return '<=';
"["                 return '[';
"settings]"         return 'SETTINGS';
"tables]"           return 'TABLES';
"relationships]"    return 'RELATIONSHIPS';
"]"                 return ']';
{text}              return 'TEXT';
<<EOF>>             return 'EOF';

/lex

%left ','

%start source 

%%

source
    : content EOF
        { 
            console.log(yy.regions); 
            console.log("\n" + JSON.stringify(yy.regions)); 
            return yy.regions; 
        }
    | NEWLINE content EOF
        { 
            console.log(yy.regions); 
            console.log("\n" + JSON.stringify(yy.regions)); 
            return yy.regions; 
        }
    | NEWLINE EOF
    | EOF
    ;

content
    : '[' section content
    | '[' section
    ;

section
    : SETTINGS NEWLINE settings_content 
    | TABLES NEWLINE tables_content
    | RELATIONSHIPS NEWLINE relationships_content
    ; 

settings_content
    : settings_line NEWLINE settings_content
    | settings_line NEWLINE
    | settings_line
    ;

settings_line
    : text '=' text
        { yy.regions.settings[$1] = $3; }
    ;

tables_content
    : tables_line NEWLINE tables_content
    | tables_line NEWLINE
    | tables_line 
    ;

tables_line
    : table_name
        { yy.regions.tables.push({ name: $table_name, fields: [] }); }
    | field_list
        {
            var tableCount = yy.regions.tables.length;
            var tableIndex = tableCount - 1;
            yy.regions.tables[tableIndex].fields.push($field_list);
         }
    ;

table_name
    : '-' text
        { $$ = $text; }
    ;

field_list
    : text
        { $$=[]; $$.push($text); }
    | field_list ',' text
        { $field_list.push($text); $$ = $field_list; }
    ;

relationships_content
    : relationships_line NEWLINE relationships_content
    | relationships_line NEWLINE
    | relationships_line 
    ; 

relationships_line
    : relationship_key '=>' relationship_key 
        { 
            yy.regions.relationships.push({
                pkTable: $1,
                fkTable: $3
            }); 
        }
    | relationship_key '<=' relationship_key
        {
            yy.regions.relationships.push({
                pkTable: $3,
                fkTable: $1
            }); 
        }
    ;

relationship_key
    : text '.' text
        { $$ = { name: $1, field: $3 };  }
    | text
        { $$ = { name: $1 }; }
    ;

text
    : TEXT
        { $$ = $TEXT; }
    ;

它用于解析这种代码：

[settings]
DefaultFieldType = string

[tables]
-table1
id, int, PK
username, string, NULL
password, string

-table2
id, int, PK
itemName, string
itemCount, int

[relationships]
table1 => table2
foo.test => bar.test2

进入这种JSON：

{ settings: { DefaultFieldType: 'string' },
  tables:
   [ { name: 'table1', fields: [Object] },
     { name: 'table2', fields: [Object] } ],
  relationships:
   [ { pkTable: [Object], fkTable: [Object] },
     { pkTable: [Object], fkTable: [Object] } ] }

但是我没有语法错误。当我转到Jison demo并尝试解析5*PI 3^2时，我收到以下错误：

Parse error on line 1:
5*PI 3^2
-----^
Expecting 'EOF', '+', '-', '*', '/', '^', ')', got 'NUMBER'

这是预料之中的。但是，当我更改我想要解析的代码的最后一行时：

foo.test => bar.test2

类似

foo.test => a bar.test2

我收到以下错误：

throw new _parseError(str, hash);
      ^
TypeError: Function.prototype.toString is not generic

我将其跟踪到生成的解析器代码，如下所示：

if (hash.recoverable) {
    this.trace(str);
} else {
    function _parseError (msg, hash) {
        this.message = msg;
        this.hash = hash;
    }
    _parseError.prototype = Error;

    throw new _parseError(str, hash);
}

因此，这让我相信我编写代码的方式以及处理解析的方式有问题，但我不知道可能是什么。

好像它可能与error recovery有关。如果这是正确的，应该如何使用？我是否应该将“错误”规则向上添加到源根目录的每个元素？

Answer 1

您的语法似乎在Jison演示页面中按预期工作，至少使用我正在使用的浏览器（Firefox 46.0.1）。根据您引用的代码周围的git存储库中的活动量，我怀疑您使用的jison版本有一个错误：

我认为演示页面上的jison版本较旧，而不是更新版本，因此如果从github获取当前代码不起作用，您可以尝试使用旧版本。

为什么我在Jison中的语法错误没有被“传播”？

1 个答案: