Question

我正在尝试复制＆amp;将多个文件夹粘贴到单个文件夹中，这是一个简单的备份/恢复过程。我可以使用以下内容创建备份副本：

for /d %%G in ("AppSettings\AppName version ?.?.?") do xcopy /e/h/k/c/i "%%~G" "%%~G_BACKUP"

我可以使用相同的变体删除它们：

do rd /s /q "%%~G"

但我无法“恢复”，因为我无法使用相同的过程修剪名称中的“_BACKUP”...工作文件夹名称是严格的，它必须是“AppName Vesrion＃。＃。＃。 “。

任何建议将不胜感激：）

Answer 1

为什么不（如果原始目录没有被删除）

for /d %%G in ("AppSettings\AppName version ?.?.?") do xcopy /e/h/k/c/i "%%~G_BACKUP" "%%~G"

或

SetLocal EnableDelayedExpansion
for /d %%G in ("AppSettings\AppName version ?.?.?_BACKUP") do (
  set "originalPath=%%G" 
  set "originalPath=!originalPath:_BACKUP=!"
  xcopy /e/h/k/c/i "%%~G" "!originalPath!"
)
EndLocal

set＆＃34; originalPath =！originalPath：_BACKUP =！＆＃34; 将从originalPath删除_BACKUP的任何错误

Answer 2

for /d %%G in ("AppSettings\AppName version ?.?.?_BACKUP") do (
  for /F "tokens=1 delims=_" %%g in ("%%~nxG") do (
    if exist "%%~dpG%%g" (
         rem next xcopy might ask Overwrite <full file path> (Yes/No/All)? 
      xcopy /e/h/k/c/i "%%~G" "%%~dpG%%g"
    ) else (
      move "%%~G" "%%g"
    )
  )
)

资源（必读）：

（命令参考）An A-Z Index of the Windows CMD command line
（其他特殊情况）Windows CMD Shell Command Line Syntax
（%%~nxG等特殊页面）Command Line arguments (Parameters)

Windows批量复制具有名称修剪的多个文件夹

2 个答案: