Question

我正在尝试在电子邮件和电子邮件守护程序中创建一个报告，如果它们长度超过2040个字符则会删除。我正在使用XSLT来构建电子邮件报告，我需要分解这些行，但我仍然需要链接才能工作。

<xsl:variable name="encoded_url">
    <xsl:value-of select="saxon:string-to-base64Binary(concat(PROTOCOL,'://',URL),'UTF8')" xmlns:saxon="http://saxon.sf.net/"/>
</xsl:variable>
<dd style="{$style-dd}">
    <a title="View URL"
        href="{$baseHref}report?url={$encoded_url}" style="{$style-links}">
        <xsl:call-template name="break-url" >
            <xsl:with-param name="url" select="URL" />
            <xsl:with-param name="length">75</xsl:with-param>
            <xsl:with-param name="lines">999</xsl:with-param>
        </xsl:call-template>
    </a>

这不是我的代码，我不熟悉XSL，但我在这里和网上搜索过，我并没有真正看到一个很棒的解决方案。

Answer 1

此XPath 2.0表达式：

string-join(for $line in tokenize(line,'&#xA;'),
                $length in string-length($line)
            return if ($length > $pMaxLength)
                   then substring(replace($line,
                                          concat('(.{1,',
                                                 $pMaxLength,
                                                 '})'),
                                          '$1&#xA;'),
                                  1,
                                  $length + ceiling($length div $pMaxLength) -1)
                   else $line,
            '&#xA;')

对于测试，此输入：

<line>
line1
line2 line2 line2 line2
line3line3
line4line4
line5line5line5line5line5
</line>

使用此XSLT 2.0样式表：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:param name="pMaxLength" select="10"/>
    <xsl:template match="/">
        <xsl:value-of
         select="string-join(
                     for $line in tokenize(line,'&#xA;'),
                         $length in string-length($line)
                     return if ($length > $pMaxLength)
                            then substring(replace($line,
                                                   concat('(.{1,',
                                                          $pMaxLength,
                                                          '})'),
                                                   '$1&#xA;'),
                                           1,
                                           $length +
                                           ceiling($length div $pMaxLength) - 1)
                            else $line,
                     '&#xA;')"/>
    </xsl:template>
</xsl:stylesheet>

输出：

line1
line2 line
2 line2 li
ne2
line3line3
line4line4
line5line5
line5line5
line5

以防万一，这个XSLT 1.0样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="line/text()" name="lines">
        <xsl:param name="pString" select="."/>
        <xsl:param name="pMaxLength" select="10"/>
        <xsl:choose>
            <xsl:when test="contains($pString,'&#xA;')">
                <xsl:call-template name="lines">
                    <xsl:with-param name="pString" 
                     select="substring-before($pString,'&#xA;')"/>
                    <xsl:with-param name="pMaxLength" 
                     select="$pMaxLength"/>
                </xsl:call-template>
                <xsl:call-template name="lines">
                    <xsl:with-param name="pString" 
                     select="substring-after($pString,'&#xA;')"/>
                    <xsl:with-param name="pMaxLength" 
                     select="$pMaxLength"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="concat(substring($pString,1,$pMaxLength),
                                             '&#xA;')"/>
                <xsl:apply-templates 
                 select="current()[string-length($pString) > $pMaxLength]">
                    <xsl:with-param name="pString"
                     select="substring($pString,$pMaxLength+1)"/>
                    <xsl:with-param name="pMaxLength" select="$pMaxLength"/>
                </xsl:apply-templates>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

如何限制电子邮件XSLT的行长度

1 个答案: