Question

我有基于hyperloglog的示例。我尝试将Container的大小进行参数化，并使用reflection在容器的函数中使用此参数。

import           Data.Proxy
import           Data.Reflection

newtype Container p = Container { runContainer :: [Int] }
    deriving (Eq, Show)

instance Reifies p Integer => Monoid (Container p) where
  mempty = Container $ replicate (fromIntegral (reflect (Proxy :: Proxy p))) 0
  mappend (Container l) (Container r) = undefined

我的跛脚Monoid实例根据已知参数定义mempty，并执行一些＆＃34; type-safe＆＃34; mappend。当我试图对不同大小的容器进行求和时，它会很好地工作，但是没有出现类型错误。

但是仍然可以使用coerce欺骗它，我正在寻找在编译时阻止它的方法：

ghci> :set -XDataKinds
ghci> :m +Data.Coerce
ghci> let c3 = mempty :: Container 3
ghci> c3
ghci> Container {runContaner: [0,0,0]}
ghci> let c4 = coerce c3 :: Container 4
ghci> :t c4
ghci> c4 :: Container 4
ghci> c4
ghci> Container {runContainer: [0,0,0]}

添加类型角色没有帮助

type role Container nominal

Answer 1

问题是只要构造函数在范围内，newtype对它们的表示是可强制的 - 事实上，这是Coercible的动机的一个重要部分。并且Coercible约束就像任何其他类型类约束一样，并且会自动搜索并放在一起，只有更多。因此，coerce c3发现你有

instance Coercible (Container p) [Int]
instance Coercible [Int] (Container p')

适用于所有p和p'，并愉快地通过

为您构建复合强制

instance (Coercible a b, Coercible b c) => Coercible a c

如果你不导出Container构造函数 - 就像你可能想要做的那样！ - 然后不再知道newtype等于它的表示（你丢失了上面的前两个实例），并且你在其他模块中得到了所需的错误：

ContainerClient.hs:13:6:
    Couldn't match type ‘4’ with ‘3’
    arising from trying to show that the representations of
      ‘Container 3’ and
      ‘Container 4’ are the same
    Relevant role signatures: type role Container nominal nominal
    In the expression: coerce c3
    In an equation for ‘c4’: c4 = coerce c3

但是，您始终可以在定义newtype的模块中（通过coerce或其他方式）中断不变量。

作为旁注，你可能不想在这里使用记录式访问器并将其导出;它允许用户使用记录更新语法来更改你下面的代码，所以

c3 :: Container 3
c3 = mempty

c3' :: Container 3
c3' = c3{runContainer = []}

变得有效。让runContainer成为一个独立的功能。

我们可以通过在定义newtype的模块中查看Core（通过-ddump-simpl）来验证我们是否获得了两个Container - 表示约束的组合（其中我也叫Container），输出是（如果我们删除导出列表）

c4 :: Container 4
[GblId, Str=DmdType]
c4 =
  c3
  `cast` (Container.NTCo:Container[0] <GHC.TypeLits.Nat>_N <3>_N
          ; Sym (Container.NTCo:Container[0] <GHC.TypeLits.Nat>_N <4>_N)
          :: Container 3 ~R# Container 4)

这有点难以理解，但重要的是Container.NTCo:Container[0]：NTCo是newtype newtype之间的Container p强制它的表示类型。 Sym转过来，;组成两个约束。

调用最终约束γₓ;然后整个打字派生是

Sym :: (a ~ b) -> (b ~ a)
-- Sym is built-in

(;) :: (a ~ b) -> (b ~ c) -> (a ~ c)
-- (;) is built-in

γₙ :: k -> (p :: k) -> Container p ~ [Int]
γₙ k p = Container.NTCo:Container[0] <k>_N <p>_N

γ₃ :: Container 3 ~ [Int]
γ₃ = γₙ GHC.TypeLits.Nat 3

γ₄ :: Container 4 ~ [Int]
γ₄ = γₙ GHC.TypeLits.Nat 4

γ₄′ :: [Int] ~ Container 4
γ₄′ = Sym γ₄

γₓ :: Container 3 ~ Container 4
γₓ = γ₃ ; γ₄′

以下是我使用的源文件：

Container.hs：

{-# LANGUAGE FlexibleContexts, UndecidableInstances, ScopedTypeVariables,
             RoleAnnotations, PolyKinds, DataKinds #-}

module Container (Container(), runContainer) where

import Data.Proxy
import Data.Reflection
import Data.Coerce

newtype Container p = Container { runContainer :: [Int] }
    deriving (Eq, Show)
type role Container nominal

instance Reifies p Integer => Monoid (Container p) where
  mempty = Container $ replicate (fromIntegral (reflect (Proxy :: Proxy p))) 0
  mappend (Container l) (Container r) = Container $ l ++ r

c3 :: Container 3
c3 = mempty

-- Works
c4 :: Container 4
c4 = coerce c3

ContainerClient.hs：

{-# LANGUAGE DataKinds #-}

module ContainerClient where

import Container
import Data.Coerce

c3 :: Container 3
c3 = mempty

-- Doesn't work :-)
c4 :: Container 4
c4 = coerce c3

禁用Haskell类型强制

1 个答案: