Question

我在erlang中有记录：

-record(myrec,
    { 
      id = 0,
      price = 0,
      quantity = 0
    }).

然后我有一个记录列表，我希望按ID和价格排序，按降序和升序排序，其中price是第一个键，如果两个记录具有相同的价格，我想按ID排序。 / p>

我怎样才能为此定义乐趣？

我是Erlang的新手：）

感谢， nisbus

Answer 1

这是一个比目前为止所建议的更短的解决方案。首先定义你的记录：

1> rd(myrec, {id=0, price=0, quantity=0}).
myrec

然后让我们发明其中的三个：

2> A = #myrec{id=1, price=10, quantity=2}, B = #myrec{id=2, price=4, quantity=3}, C = #myrec{id=3, price=10, quantity=1}.
#myrec{id = 3,price = 10,quantity = 1

现在我们需要一个比较功能。这是解决方案更短的地方。 Erlang可以按照它们出现的顺序比较元组的术语，所以如果我们想按价格排序，那么按id，我们只需要比较{PriceA, IdA} < {PriceB, IdB}形式的两个元组：

3> F = fun(X, Y) -> {X#myrec.price, X#myrec.id} < {Y#myrec.price, Y#myrec.id} end.
#Fun<erl_eval.12.113037538>

并将其插入lists:sort/2：

4> lists:sort(F, [C,B,A]).
[#myrec{id = 2,price = 4,quantity = 3},
 #myrec{id = 1,price = 10,quantity = 2},
 #myrec{id = 3,price = 10,quantity = 1}]

订单现在为[B, A, C]，您的列表已排序。

请注意，如果您希望按降序 ID进行排序，可以通过按如下方式反转元组中的ID来欺骗它：

5> G = fun(X, Y) -> {X#myrec.price, Y#myrec.id} < {Y#myrec.price, X#myrec.id} end.
#Fun<erl_eval.12.113037538>
6> lists:sort(G, [C,B,A]).                                                       
[#myrec{id = 2,price = 4,quantity = 3},
 #myrec{id = 3,price = 10,quantity = 1},
 #myrec{id = 1,price = 10,quantity = 2}]

给我们[B, C, A]。这对读者来说并不明显，因此在这种情况下，您最好将其记录下来或使用Dustin的解决方案。这里提出的解决方案的优点是不需要嵌套。通过在比较中的任一元组中设置元素，您可以根据需要对它们进行相当多的比较，而不会使代码更长。

Answer 2

首先，您要弄清楚如何比较您的记录：

-spec compare(#myrec{}, #myrec{}) -> boolean().
compare(A, B) ->
    case A#myrec.price == B#myrec.price of
        true ->
            A#myrec.id < B#myrec.id;
        _ ->
            B#myrec.price < A#myrec.price
    end.

然后，你只需使用普通的lists:sort函数和你的比较函数来得到你想要的东西（这是我上面运行的eunit测试，以确保我做了一些有意义的事情）：

compare_test() ->
    R1 = #myrec{id=5, price=3, quantity=2},
    R2 = #myrec{id=6, price=5, quantity=1},
    R3 = #myrec{id=7, price=5, quantity=0},

    false = compare(R1, R2),
    true = compare(R2, R1),

    true = compare(R2, R3),
    false = compare(R3, R2),

    false = compare(R1, R3),
    true = compare(R3, R1),

    % Run a sort with the above comparator.
    [R2, R3, R1] = lists:sort(fun compare/2, [R1, R2, R3]).

Answer 3

% 3723064

-module(t).
-export([record_sort/0, price_cmp/2, qty_cmp/2]).

-record (item, {id = 0, price = 0, quantity = 0}).

price_cmp(A, B) ->
    A#item.price < B#item.price.

qty_cmp(A, B) ->
    A#item.quantity < B#item.quantity.

record_sort() -> 
    Items = [ 
        #item{id=1, price=10, quantity=5},
        #item{id=2, price=50, quantity=0},
        #item{id=3, price=30, quantity=3},
        #item{id=4, price=60, quantity=9}
    ],
    io:format("Unsorted Items: ~p~n", [Items]),
    io:format("By Price: ~p~n", [lists:sort({t, price_cmp}, Items)]),
    io:format("By Quantity: ~p~n", [lists:sort({t, qty_cmp}, Items)]).

    % Alternatively use anonymous functions:

    % io:format("By Price: ~p~n", [lists:sort(
    %   fun(A, B) -> A#item.price < B#item.price end, Items)]),
    % 
    % io:format("By Quantity: ~p~n", [lists:sort(
    %   fun(A, B) -> A#item.quantity < B#item.quantity end, Items)]).

这将产生（假设示例文件t.erl）：

1> c(t).           
{ok,t}
2> t:record_sort().
Unsorted Items: [{item,1,10,5},{item,2,50,0},{item,3,30,3},{item,4,60,9}]
By Price: [{item,1,10,5},{item,3,30,3},{item,2,50,0},{item,4,60,9}]
By Quantity: [{item,2,50,0},{item,3,30,3},{item,1,10,5},{item,4,60,9}]
ok

在列表中排序Erlang记录？

3 个答案: