检查是否存在任何个形状

Question

如何检查工作表中是否存在任何形状？

我使用了以下代码：

Sub my()
    Dim shp As Shape
    If Not shp Is Nothing Then
        For Each shp In Sheet1.Shapes
            mesage = shp.TopLeftCell.Address(0, 0)
        Next shp
    Else
        mesage = Sheet1.Cells(1, 12).Address
    End If

End Sub

由于我没有给出形状名称，它正在执行'if-else'循环的'else'部分。

我不能在这里给出形状名称，因为每次形状名称都不同。

Answer 1

检查是否存在任何个形状

如果要检查活动工作表上是否有任何 VBA Shapes，则只需检查.Count property中Shapes object的值即可：

ActiveSheet.Shapes.Count

...，它将返回形状的数量，如果没有形状，则返回零。

用法示例：

If ActiveSheet.Shapes.Count = 0 Then MsgBox "No shapes found!"

检查是否存在特定形状

如果需要检查是否存在特定形状，请使用以下功能：

Function shapeExists(shapeName As String) As Boolean
'returns TRUE if a shape named [ShapeName] exists on the active worksheet
    Dim sh As Shape
    For Each sh In ActiveSheet.Shapes
         If sh.Name = shapeName Then shapeExists = True
    Next sh
End Function

用法示例：

If Not shapeExists("My Shape Name") Then MsgBox "Shape not found!"

列出所有形状

在立即窗口中列出活动工作表上的所有形状。（按 Ctrl + G 将其打开。）

Sub ListAllShapes()
'list all shapes on the active worksheet
    Dim sh As Shape
    For Each sh In ActiveSheet.Shapes
        Debug.Print "id=" & sh.ID, "name=" & sh.Name
    Next sh
End Sub

删除所有形状

从活动工作表中删除所有形状。

Sub DeleteAllShapes()
'delete all shapes on the active worksheet (Including CONTROLS, so use with caution!)
    Dim sh As Shape
    For Each sh In ActiveSheet.Shapes
        sh.Delete
    Next sh
End Sub

如何检查是否存在任何形状？

1 个答案:

检查是否存在任何个形状

检查是否存在特定形状

列出所有形状

删除所有形状

更多信息：