Question

我有这个示例XML数据（简化为基础知识）：

<?xml version="1.0" encoding="UTF-8"?>
<AssignmentHistory Version="1610">
    <W20160104>
        <Chairman>Name1</Chairman>
    </W20160104>
    <W20160111>
        <Chairman>Name2</Chairman>
    </W20160111>
</AssignmentHistory>

它包含WYYYYNNDD个节点的列表。目前我正在这样的XSL脚本中访问此列表（再次，这是一个减少的例子）：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" indent="yes" version="4.01"
    doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"
    doctype-public="//W3C//DTD XHTML 1.0 Transitional//EN"/>
  <xsl:template match="/">
    <html xmlns="http://www.w3.org/1999/xhtml">
      <head>
        <meta content="text/html; charset=utf-8" http-equiv="Content-Type" />
        <!--<link rel="stylesheet" type="text/css" href="Workbook-off.css"/>-->
        <title>Custom Report</title>
      </head>
      <body>
        <xsl:variable name="AssignHistory" select="document('AssignHistory.xml')"/>
        <xsl:for-each select="$AssignHistory/AssignmentHistory/*">
          <xsl:apply-templates select="Chairman"></xsl:apply-templates>
        </xsl:for-each>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="Chairman">
    <p>
      <xsl:text>Chairman: </xsl:text>
      <xsl:value-of select="."/>
    </p>
  </xsl:template>
</xsl:stylesheet>

我想要做的是在for-each循环期间转换"."的内容（这将是 WYYYYMMDD 的值）并将其显示为标准短日期（例如，dd / mm / yyyy）。

我不知道该怎么做。感谢您对此问题的指导。非常感谢。

预期结果：

04/01/2016
Chairman: Name1
11/01/2016
Chairman: Name2

最终事情会发生变化并变得更加复杂。

Answer 1

这相当简单 - 尝试：

<xsl:template match="Chairman">
    <xsl:variable name="datestr" select="name(..)" />
    <p>
        <xsl:value-of select="substring($datestr, 8, 2)"/>
        <xsl:text>/</xsl:text>
        <xsl:value-of select="substring($datestr, 6, 2)"/>
        <xsl:text>/</xsl:text>
        <xsl:value-of select="substring($datestr, 2, 4)"/>
        <br/>
        <xsl:text>Chairman: </xsl:text>
        <xsl:value-of select="."/>
    </p>
</xsl:template>

使用XML和XSL将文本节点格式化为日期？

1 个答案: