Question

我正在使用AoA在Perl中构建计数矩阵：my @aoa = ()然后每当我需要递增特定单元格时调用$aoa[$i][$j]++。由于某些单元格根本没有增加，所以它们会保留undef（这相当于0计数）。

我想从矩阵中打印一些行，但我得到undef个单元格的错误（我只想将其打印为零）。我该怎么办？

Answer 1

将defined与条件运算符?:）一起使用。

#!/usr/bin/perl

use strict;
use warnings;

my @matrix;

for my $i (0 .. 3) {
    for my $j (0 .. 3) {
        if (rand > .5) {
            $matrix[$i][$j]++;
        }
    }
}

for my $aref (@matrix) {
    print join(", ", map { defined() ? $_ : 0 } @{$aref}[0 .. 3]), "\n"
}

如果您使用的是Perl 5.10或更高版本，则可以使用defined-or运算符（//）。

#!/usr/bin/perl

use 5.012;
use warnings;

my @matrix;

for my $i (0 .. 3) {
    for my $j (0 .. 3) {
        if (rand > .5) {
            $matrix[$i][$j]++;
        }
    }
}

for my $aref (@matrix) {
    print join(", ", map { $_ // 0 } @{$aref}[0 .. 3]), "\n"
}

Answer 2

古典：

print defined $aoa[$i][$j] ? $aoa[$i][$j] : 0;

Modern Perl（5.10或更高版本）：

print $aoa[$i][$j] // 0;

这是更简洁和Perlish，不得不说。

或者，在打印前运行矩阵，将undef替换为0。

use strict;
use warnings;

my @aoa = ();

$aoa[1][1] = 1;
$aoa[0][2] = 1;
$aoa[2][1] = 1;

for my $i (0..2)
{
    print join ",", map { $_ // 0 } @{$aoa[$i]}[0..2], "\n";
}

Answer 3

举个例子，请根据您的要求修改代码。

use strict;
use warnings;

my @aoa;

$aoa[1][3]++;

foreach my $i (1 .. 3){
    foreach my $j (1 .. 3){
        defined $aoa[$i][$j] ? print $aoa[$i][$j] : print "0";
        print "\t";
    }
    print "\n";
}

如何在Perl中将undef值打印为零？

3 个答案: